7 IF Statements.............

[Omer]

Hi,

My data is as follows and I am trying to write IF
Statemtns ( 6-7 IF statemts all in one) Can someone please
help, all I am trying to do is compare todays' number in
Column B vs Yesterdays numbers in Column B, if it was a
+ve number which column's (C,D,E,f) were aslo +ve
Yesterday.

What do I want: Column B is the center of Focus. If B
increases or decreases compared to its previous days close
(B2-B1), then were C1, D1, E1 or F1 also +VE or was one -
VE and if so which ones.

Example: B2-B1 is +0.16 at the same time C,D,E were also
+VE, but F was -VE. Now if you look at B4-B3 it is -1.32,
but D3 is a positive number the others are -VE. HOW can we
write all this in an Excell statement

Thanks for your help in advance
Omer
A B C D E F
10.21.03 73.21 4.5 20.75 4.8 -130
10.22.03 73.37 -60 -89 -66 -141
10.23.03 72.71 -39 6 -45 -554
10.24.03 71.39 1.98 -44 -1 0.54
10.27.03 71.58 40 64 12 118
10.28.03 72.07 45 69 21 106
10.29.03 72.45 14 28 -7 178
10.30.03 72.88 20 24 35 -41
10.31.03 73.15 -14 16 -13 -135
11.03.03 72.49 65 88 45 0
11.04.03 72.52 -14 -2 -2 288
11.05.03 73.02 -11 -20 -27 21
11.06.03 72.56 18 16 20 -285

 

[Guest]

I'm not positive this is what you're looking for, but try
this out: (returns "+" if all are positive, "-"
or "FALSE" if any are negative)
=IF((B2-B1)>0,IF((C2-C1)>0,IF((D2-D1)>0,IF((F2-F1)>0,"+","-
"))),"-"),"-")

I love IF statements. If this isn't it, it may get you
closer.

 

[OMer]

Thanks for your help.

How would you capture if only some are +Ve or if selected
are -VE

Thanks
Omer

 

[Harlan Grove]

My data is as follows and I am trying to write IF
Statemtns ( 6-7 IF statemts all in one) Can someone please
help, all I am trying to do is compare todays' number in
Column B vs Yesterdays numbers in Column B, if it was a
+ve number which column's (C,D,E,f) were aslo +ve
Yesterday.

What do I want: Column B is the center of Focus. If B
increases or decreases compared to its previous days close
(B2-B1), then were C1, D1, E1 or F1 also +VE or was one -
VE and if so which ones.

Example: B2-B1 is +0.16 at the same time C,D,E were also
+VE, but F was -VE. Now if you look at B4-B3 it is -1.32,
but D3 is a positive number the others are -VE. HOW can we
write all this in an Excell statement

...

If your range were in A1:F13, and realizing that if the change in col B from row
to row were the key factor, then there are only 12 results (differences) rather
than 13, then the following statistics may be calculated with the corresponding
array formulas.

B increase, C-F all +
=SUM((B2:B13-B1:B12>0)*(MMULT(--(C2:F13>0),{1;1;1;1})=4))

B increase, C-F some but not all +
=SUM((B2:B13-B1:B12>0)*(ABS(MMULT(--(C2:F13>0),{1;1;1;1})-2)<2))

B increase, C-F none +
=SUM((B2:B13-B1:B12>0)*(MMULT(--(C2:F13>0),{1;1;1;1})=0))

B decrease, C-F all +
=SUM((B2:B13-B1:B12<0)*(MMULT(--(C2:F13>0),{1;1;1;1})=4))

B decrease, C-F some but not all +
=SUM((B2:B13-B1:B12<0)*(ABS(MMULT(--(C2:F13>0),{1;1;1;1})-2)<2))

B decrease, C-F none +
=SUM((B2:B13-B1:B12<0)*(MMULT(--(C2:F13>0),{1;1;1;1})=0))

If this isn't useful, what exactly are you trying to calculate?