Add CC addresses in Macro Merge

[GeorgeA]

Hello,
I use the macro below to create and send an HTML email merge with
attachments. It references a directory that stores the To email address and
attachment link. I would like to cc 2 other people on each email and hope
someone can help me with the code. If a dialogue box simply asked who should
be cc'd, that would be fine (as long as I can enter multiple addresses).

Thanks very much!

Sub emailmergewithattachments()
'To create the email messages in HTML format
Dim source As Document, Maillist As Document, TempDoc As Document
Dim datarange As Range
Dim i As Long, j As Long
Dim bStarted As Boolean
Dim oOutlookApp As Outlook.Application
Dim oItem As Outlook.MailItem
Dim mysubject As String, message As String, Title As String
Set source = ActiveDocument
' Check if Outlook is running. If it is not, start Outlook
On Error Resume Next
Set oOutlookApp = GetObject(, "Outlook.Application")
If Err <> 0 Then
Set oOutlookApp = CreateObject("Outlook.Application")
bStarted = True
End If
' Open the catalog mailmerge document
With Dialogs(wdDialogFileOpen)
.Show
End With
Set Maillist = ActiveDocument
' Show an input box asking the user for the subject to be inserted into the
email messages
message = "Enter the subject to be used for each email message."
' Set prompt.
Title = " Email Subject Input"
' Set title.
' Display message, title
mysubject = InputBox(message, Title)
' Iterate through the Sections of the Source document and the rows of the
catalog mailmerge document,
' extracting the information to be included in each email.
For j = 1 To source.Sections.Count
source.Sections(j).Range.Copy
Set oItem = oOutlookApp.CreateItem(olMailItem)
With oItem
.Subject = mysubject
.BodyFormat = olFormatHTML
.Display
Set objDoc = .GetInspector.WordEditor
Set objSel = objDoc.Windows(1).Selection
objSel.Paste
Set datarange = Maillist.Tables(1).Cell(j, 1).Range
datarange.End = datarange.End - 1
.To = datarange
For i = 2 To Maillist.Tables(1).Columns.Count
Set datarange = Maillist.Tables(1).Cell(j, i).Range
datarange.End = datarange.End - 1
.Attachments.Add Trim(datarange.Text), olByValue, 1
Next i
.Send
End With
Set oItem = Nothing
Next j
Maillist.Close wdDoNotSaveChanges
' Close Outlook if it was started by this macro.
If bStarted Then
oOutlookApp.Quit
End If
MsgBox source.Sections.Count & " messages have been sent."
'Clean up
Set oOutlookApp = Nothing
End Sub

 

[Doug Robbins - Word MVP]

Add the .cc line after the .To = DataRange

.To = DataRange
.cc = "(e-mail address removed); (e-mail address removed)"

Or, according to the Help on the .cc attribute, it may be better to use the
Recipients object of Outlook

Outlook Developer Reference
Recipients Object
Contains a collection of Recipient objects for an Outlook item.
Remarks


Use the Recipients property to return the Recipients object of an
AppointmentItem, JournalItem, MailItem, MeetingItem, or TaskItem object.

Use the Add method to create a new Recipient object and add it to the
Recipients object. The Type property of a new Recipient object is set to the
default for the associated AppointmentItem, JournalItem, MailItem, or
TaskItem object and must be reset to indicate another recipient type.

Use Recipients(index), where index is the name or index number, to return a
single Recipient object. The name can be a string representing the display
name, the alias, or the full SMTP e-mail address of the recipient.


Example


The following example creates a new MailItem object and adds Jon Grande as
the recipient using the default type ("To").

Visual Basic for Applications
Set myItem = Application.CreateItem(olMailItem)
Set myRecipient = myItem.Recipients.Add ("Jon Grande")

The following example creates the same MailItem object as the preceding
example, and then changes the type of the Recipient object from the default
("To") to CC.

Visual Basic for Applications
Set myItem = Application.CreateItem(olMailItem)
Set myRecipient = myItem.Recipients.Add ("Jon Grande")
myRecipient.Type = olCC


--
Hope this helps.

Please reply to the newsgroup unless you wish to avail yourself of my
services on a paid consulting basis.

Doug Robbins - Word MVP, originally posted via msnews.microsoft.com