Add criteria to sumproduct Greater than or equal to

[Diddy]

Hi everyone,

I’m using the following

=SUMPRODUCT(--(Data!$C$3:$C$10000=$A8),--((Data!$J$3:$J$10000=>I$6)+(Data!$J$3:$J$10000=<I$7)),--((Data!$AC$3:$AC$10000="c")+(Data!$AC$3:$AC$10000="m")))

Where I6 and I7 are two dates including and between which the data should be
included.

I’m getting too many returned, so what am I doing wrong?

Any suggestions would be brilliant

Cheers

 

[Max]

Think this part:

..,--((Data!$J$3:$J$10000=>I$6)+(Data!$J$3:$J$10000=<I$7)),..

should be multiplicative (AND)

Try (untested)
=SUMPRODUCT((Data!$C$3:$C$10000=$A8)*(Data!$J$3:$J$10000>=I$6)*(Data!$J$3:$J$10000<=I$7)*((Data!$AC$3:$AC$10000="c")+(Data!$AC$3:$AC$10000="m")))
voila? hit the YES below
--
Max
Singapore
http://savefile.com/projects/236895
Downloads:27,000 Files:200 Subscribers:70
xdemechanik
---

 

[Jacob Skaria]

Try

=SUMPRODUCT((Data!$C$3:$C$10000=$A8)*(Data!$J$3:$J$10000>=I$6)*(Data!$J$3:$J$10000<=I$7)*(Data!$AC$3:$AC$10000={"c","m"}))

If this post helps click Yes

 

[Diddy]

Thank you Max just the job

Think this part:
should be multiplicative (AND)

Try (untested):
=SUMPRODUCT((Data!$C$3:$C$10000=$A8)*(Data!$J$3:$J$10000>=I$6)*(Data!$J$3:$J$10000<=I$7)*((Data!$AC$3:$AC$10000="c")+(Data!$AC$3:$AC$10000="m")))
voila? hit the YES below
--
Max
Singapore
http://savefile.com/projects/236895
Downloads:27,000 Files:200 Subscribers:70
xdemechanik

 

[Max]

Welcome, glad to hear
--
Max
Singapore
http://savefile.com/projects/236895
Downloads:27,000 Files:200 Subscribers:70
xdemechanik

 

[Diddy]

Thank you Jacob That did the trick

Try

=SUMPRODUCT((Data!$C$3:$C$10000=$A8)*(Data!$J$3:$J$10000>=I$6)*(Data!$J$3:$J$10000<=I$7)*(Data!$AC$3:$AC$10000={"c","m"}))

If this post helps click Yes