Array not working for me...

[Dave]

Hi,
I'm using a doc with a table as a source to populate a
listbox on a userform.
The goal is for the user to choose a lastname from a
list, and get the corresponding address info into
variables for insertion into the doc. The table has 400+
rows and 3 columns. Col1 has Lastname, Col2 has 1st
address line, Col3 has the complete address resembling a
mailing label with CRs in it.
The last variable isn't getting set with the full
address. I tried changing the type to variant from string,
but it didn't help. The code is listed below.

Thanks in advance for any help!


Private Sub cmdCancel_Click()
frmGetAdd.Hide
End Sub

Private Sub cmdOK_Click()
Dim ListReturn As Integer
ListReturn = frmGetAdd.lstMDNames.ListIndex
ListReturn = ListReturn + 1
frmGetAdd.Hide
vAddressee = arrAddBook(ListReturn, 2)
vAddress = arrAddBook(ListReturn, 3)
MsgBox ("Addressee is " & vAddressee & vbNewLine & _
"Address is " & vAddress)
End Sub

Private Sub UserForm_Initialize()
Documents.Open FileName:="C:\documed\blanks\OSC
AddBook.doc"
With ActiveDocument.Tables(1)
Dim rcount As Integer
rcount = .Rows.Count
ReDim arrAddBook(1 To rcount, 3) As Variant
For i = 1 To rcount
arrAddBook(i, 0) = .Cell(i, 0).Range.Text
arrAddBook(i, 1) = .Cell(i, 1).Range.Text
arrAddBook(i, 2) = .Cell(i, 2).Range.Text
Next i
End With
ActiveDocument.Close wdDoNotSaveChanges
With frmGetAdd.lstMDNames
For r = 1 To rcount
.AddItem arrAddBook(r, 0)
Next r
End With

End Sub

 

[Doug Robbins - Word MVP]

Hi Dave,

This routine loads a listbox with client details stored in a table in a
separate
document (which makes it easy to maintain with additions, deletions etc.),
that document being saved as Clients.Doc for the following code.

On the UserForm, have a list box (ListBox1) and a Command Button
(CommandButton1) and use the following code in the UserForm_Initialize() and
the CommandButton1_Click() routines

Private Sub UserForm_Initialize()
Dim sourcedoc As Document, i As Integer, j As Integer, myitem As Range,
m As Long, n As Long
' Modify the path in the following line so that it matches where you
saved Suppliers.doc
Application.ScreenUpdating = False
' Open the file containing the client details
Set sourcedoc = Documents.Open(FileName:="e:\worddocs\Clients.doc")
' Get the number or clients = number of rows in the table of client
details less one
i = sourcedoc.Tables(1).Rows.Count - 1
' Get the number of columns in the table of client details
j = sourcedoc.Tables(1).Columns.Count
' Set the number of columns in the Listbox to match
' the number of columns in the table of client details
ListBox1.ColumnCount = j
' Define an array to be loaded with the client data
Dim MyArray() As Variant
'Load client data into MyArray
ReDim MyArray(i, j)
For n = 0 To j - 1
For m = 0 To i - 1
Set myitem = sourcedoc.Tables(1).Cell(m + 2, n + 1).Range
myitem.End = myitem.End - 1
MyArray(m, n) = myitem.Text
Next m
Next n
' Load data into ListBox1
ListBox1.List() = MyArray
' Close the file containing the client details
sourcedoc.Close SaveChanges:=wdDoNotSaveChanges
End Sub

Private Sub CommandButton1_Click()
Dim i As Integer, Addressee As String
Addressee = ""
For i = 1 To ListBox1.ColumnCount
ListBox1.BoundColumn = i
Addressee = Addressee & ListBox1.Value & vbCr
Next i
ActiveDocument.Bookmarks("Addressee").Range.InsertAfter Addressee
UserForm2.Hide
End Sub

The Initialize statement will populate the listbox with the data from the
table and then when a client is selected in from the list and the command
button is clicked, the information for that client will be inserted into a
bookmark in the document. You may want to vary the manner in which it is
inserted to suit our exact requirements, but hopefully this will get you
started.

To make it easy for you, the code has been written so that it will deal with
any number of clients and any number of details about each client. It
assumes that the first row of the table containing the client details is a
header row.

Please post any further questions or followup to the newsgroups for the
benefit of others who may be interested. Unsolicited questions forwarded
directly to me will only be answered on a paid consulting basis.

Hope this helps
Doug Robbins - Word MVP

 

[Dave]

(Even though I'm clicking 'Post Reply' I keep getting
a 'New Post'! It's refusing to follow the thread!)

Doug! Besides for having a project that now works, this
was extremely eye-opening! Numbering the columns and rows
is clear to me now, but the power of dimming 'AS' and
using the object properties really escaped me till now.
Many thanks!

Your code:
For i = 1 To ListBox1.ColumnCount
ListBox1.BoundColumn = i
Addressee = Addressee & ListBox1.Value & vbCr
Next i
would loop through the table columns and 'build'
an 'address label' for insertion.

I built the table especially for this, so I pre-built
the 'address label' in col 3 to use for inserting address
at bookmark, which is handled by another user form once
the variable was set here. I needed col 2 (just the first
line of the address) to fill variable 'vAddressee' for use
elsewhere, and I needed it set now too, so I wrote:
'vAddressee and vAddress already declared _
PUBLIC in NewMacros module
frmGetAdd.lstMDNames.BoundColumn = 2
vAddressee = frmGetAdd.lstMDNames.Value
frmGetAdd.lstMDNames.BoundColumn = 3
vAddress = frmGetAdd.lstMDNames.Value

Once again, Thank you!