Converting COUNTIFS to 2003 format

[JMVenhaus]

I have the following function in an Excel 2007 workbook and it works well.

=COUNTIFS(Articles!E3:E55,"Quality of
Products",Articles!M3:M55,">0")+COUNTIFS(Articles!F3:F55,"Quality of
Products",Articles!M3:M55,">0")

How would I convert it to a format that would work in the 2003 version?

What I am trying to do is search the E and F columns for one of five topics
and count the number of times that it returns a positive score in the M
column. Separately, I count the negative resoponses so that I can chart the
number of positives and negatives for each of the five topics. If someone
has a better way to do this I would love to hear it.

Thanks

 

[Ron Coderre]

Try this:
=SUMPRODUCT((((Articles!E3:E55="Quality of Products")+
(Articles!F3:F55="Quality of Products"))>0)*(Articles!M3:M55>0))


Is that something you can work with?
Post back if you have more questions.

Regards,

Ron
Microsoft MVP - Excel

 

[Teethless mama]

SUMPRODUCT((Articles!E3:E55,"Quality of
Products")*(Articles!M3:M55,">0"))+SUMPRODUCT((Articles!F3:F55,"Quality of
Products")*(Articles!M3:M55,">0"))

 

[Teethless mama]

or...

=SUMPRODUCT((Articles!E3:F55,"Quality of Products")*(Articles!M3:M55,>0))

 

[Teethless mama]

Ignored this one.

SUMPRODUCT((Articles!E3:E55,"Quality of
Products")*(Articles!M3:M55,">0"))+SUMPRODUCT((Articles!F3:F55,"Quality of
Products")*(Articles!M3:M55,">0"))

 

[Teethless mama]

I need coffee
here is the correction...

=SUMPRODUCT((Articles!E3:F55="Quality of Products")*(Articles!M3:M55>0))

 

[Ron Coderre]

Re: =SUMPRODUCT((Articles!E3:F55="Quality of Products")*(Articles!M3:M55>0))

Don't know if this is an issue....but, if the cells in the
same row of Col_E and Col_F both contain "Quality of Products",
that formula double-counts the row.

Regards,

Ron
Microsoft MVP - Excel