Copy page of document to new document

[Daniel71]

I'm trying to write a macro that will take a large document and save each
page in it's own individual document. Is there a method to walk through a
document page by page and copy the content (and format) of each page into a
new document? Any help on how this could be accomplished would be greatly
appreciated.

Daniel

 

[Graham Mayor]

See http://www.gmayor.com/individual_merge_letters.htm which I suspect may
address your problem, or use it as background in connection with the
following macro from fellow MVP Doug Robbins that will do exactly what you
asked.

Sub SplitByPage()
Dim sPath As String
Dim sName As String
Dim Letters As Long
Dim rDoc As Document
Dim rLoad As String
Dim fDialog As FileDialog
Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)

With fDialog
.Title = "Select Folder To Save Split Files and click OK"
.AllowMultiSelect = False
.InitialView = msoFileDialogViewList
If .Show <> -1 Then
MsgBox "Cancelled By User"
Exit Sub
End If
DocDir = fDialog.SelectedItems.Item(1)
If Right(DocDir, 1) <> "\" Then DocDir = DocDir + "\"
End With

Set rDoc = ActiveDocument
With rDoc
If Len(.Path) = 0 Then
.Save
End If
If UCase(Right(.name, 1)) = "X" Then
sName = Left(.name, Len(.name) - 5)
Else
sName = Left(.name, Len(.name) - 4)
End If
rLoad = rDoc.FullName
End With
With Selection
.EndKey Unit:=wdStory
Letters = .Information(wdActiveEndPageNumber)
.HomeKey Unit:=wdStory
End With
counter = 1
While counter < Letters + 1
Application.ScreenUpdating = False
docName = DocDir _
& sName & Chr(32) & _
LTrim$(Str$(counter)) & ".doc"
ActiveDocument.Bookmarks("\page").Range.Cut
Documents.Add
With Selection
.Paste
.EndKey Unit:=wdStory
.MoveLeft Unit:=wdCharacter, Count:=1
.Delete Unit:=wdCharacter, Count:=1
End With
ActiveDocument.SaveAs FileName:=docName, _
FileFormat:=wdFormatDocument
ActiveWindow.Close
counter = counter + 1
Application.ScreenUpdating = True
Wend
rDoc.Close wdDoNotSaveChanges
Documents.Open rLoad
End Sub

--
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>
Graham Mayor - Word MVP


<>>< ><<> ><<> <>>< ><<> <>>< <>><<>