Count cells within a date range

[Dewayne]

Is there a way to count only the cells that fall within a defined date range?
Example:
Count only the number of cells in a range that fall within the date range of
7/01/06 through 7/31/o6.
Thanks for any help

 

[Biff]

Hi!

One way:

=COUNTIF(A:A,">=7/1/2006")-COUNTIF(A:A,">7/31/2006")

Better to use cells to hold the criteria:

B1 = 7/1/2006
C1 = 7/31/2006

=COUNTIF(A:A,">="&B1)-COUNTIF(A:A,">"&C1)

Format the cell as GENERAL

Biff

 

[JMB]

where your data is in A1:A10, and B1:B2 contain 7/1/06 and 7/31/06, try:

=COUNTIF(A1:A10, ">="&B1) - COUNTIF(A1:A10, ">"&B2)

 

[Don Guillett]

how about
=SUMPRODUCT((MONTH(C2:C5)=7)*1)

 

[Dave Peterson]

And to avoid the 2005, 2004, 2003, ... dates

=sumproduct(--(text(c2:c5,"yyyymm")="200607"))

 

[Don Guillett]

or
=SUMPRODUCT((YEAR(C2:C5)=2006)*(MONTH(C2:C5)=3))

 

[Dave Peterson]

or

=SUMPRODUCT((YEAR(C2:C5)=2006)*(MONTH(C2:C5)=7))

For July <vbg>!

or
=SUMPRODUCT((YEAR(C2:C5)=2006)*(MONTH(C2:C5)=3))

 

[Dewayne]

Thank you to all of you for your suggestions
--
Dewayne

or

=SUMPRODUCT((YEAR(C2:C5)=2006)*(MONTH(C2:C5)=7))

For July <vbg>!

or
=SUMPRODUCT((YEAR(C2:C5)=2006)*(MONTH(C2:C5)=3))