Create New Workbook and copy sheets from my Speadsheet

[Jeffrey]

Hi All,

Good day. My situation is this, I have a spreadsheet. I need a code
which will create a new workbook and copy the Sheets("Quotation") and
Sheets("ClientQuotation") from my spreadsheet to this new workbook.
The code also needs to rename my new workbook with the same name as my
spreadsheet but with added "-Client". For example my spreadsheet
filename is "qt Auck 1234", then the new workbook should have a name
"qt Auck 1234-Client".

Please advice from anyone.

Cheers.

Jeff

 

[Ron de Bruin]

Hi Jeffrey

Try this one that is workin in 97-2007

Remove the ' before this line if you want to close the workbook
' .Close SaveChanges:=False

There is no error testing to check if the file already exist in this example

Sub Test_Sheets_Array()
'Working in 97-2007
Dim FileExtStr As String
Dim FileFormatNum As Long
Dim Sourcewb As Workbook
Dim Destwb As Workbook
Dim TempFilePath As String
Dim TempFileName As String
Dim sh As Worksheet
Dim TheActiveWindow As Window
Dim TempWindow As Window

With Application
.ScreenUpdating = False
.EnableEvents = False
End With

Set Sourcewb = ActiveWorkbook

'Copy the sheets to a new workbook
'We add a temporary Window to avoid the Copy problem
'if there is a List or Table in one of the sheets and
'if the sheets are grouped
With Sourcewb
Set TheActiveWindow = ActiveWindow
Set TempWindow = .NewWindow
.Sheets(Array("Quotation", "ClientQuotation")).Copy
End With

'Close temporary Window
TempWindow.Close

Set Destwb = ActiveWorkbook

'Determine the Excel version and file extension/format
With Destwb
If Val(Application.Version) < 12 Then
'You use Excel 97-2003
FileExtStr = ".xls": FileFormatNum = -4143
Else
'You use Excel 2007, we exit the sub when your answer is
'NO in the security dialog that you only see when you copy
'an sheet from a xlsm file with macro's disabled.
If Sourcewb.Name = .Name Then
With Application
.ScreenUpdating = True
.EnableEvents = True
End With
MsgBox "Your answer is NO in the security dialog"
Exit Sub
Else
Select Case Sourcewb.FileFormat
Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
Case 52:
If .HasVBProject Then
FileExtStr = ".xlsm": FileFormatNum = 52
Else
FileExtStr = ".xlsx": FileFormatNum = 51
End If
Case 56: FileExtStr = ".xls": FileFormatNum = 56
Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
End Select
End If
End If
End With

' 'Change all cells in the worksheets to values if you want
' For Each sh In Destwb.Worksheets
' sh.Select
' With sh.UsedRange
' .Cells.Copy
' .Cells.PasteSpecial xlPasteValues
' .Cells(1).Select
' End With
' Application.CutCopyMode = False
' Destwb.Worksheets(1).Select
' Next sh

'Save the new workbook
TempFilePath = Application.DefaultFilePath & "\"
TempFileName = Sourcewb.Name & "-Client"

With Destwb
.SaveAs TempFilePath & TempFileName & FileExtStr, _
FileFormat:=FileFormatNum
' .Close SaveChanges:=False
End With

With Application
.ScreenUpdating = True
.EnableEvents = True
End With
End Sub


--

Regards Ron de Bruin
http://www.rondebruin.nl/tips.htm

 

[joel]

Sub NewBook()

With ThisWorkbook
.Sheets("Quotation").Copy
Set Newbk = ActiveWorkbook
.Sheets("ClientQuotation").Copy _
after:=Newbk.Sheets(1)
OldName = .Name
NewName = OldName & "-Client" & ".xls"
Newbk.SaveAs Filename:=NewName

End With

End Sub

 

[ericson75]

Sub NewBook()

With ThisWorkbook
   .Sheets("Quotation").Copy
   Set Newbk = ActiveWorkbook
   .Sheets("ClientQuotation").Copy _
      after:=Newbk.Sheets(1)
   OldName = .Name
   NewName = OldName & "-Client" & ".xls"
   Newbk.SaveAs Filename:=NewName

End With

End Sub







- Show quoted text -

Thank you thank you. It works like a spell.

 

[ericson75]

Hi Jeffrey

Try this one that is workin in 97-2007

Remove the ' before this line if you want to close the workbook
 ' .Close SaveChanges:=False

There is no error testing to check if the file already exist in this example

Sub Test_Sheets_Array()
'Working in 97-2007
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim sh As Worksheet
    Dim TheActiveWindow As Window
    Dim TempWindow As Window

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook

    'Copy the sheets to a new workbook
    'We add a temporary Window to avoid the Copy problem
    'if there is a List or Table in one of the sheets and
    'if the sheets are grouped
    With Sourcewb
        Set TheActiveWindow = ActiveWindow
        Set TempWindow = .NewWindow
        .Sheets(Array("Quotation", "ClientQuotation")).Copy
    End With

    'Close temporary Window
    TempWindow.Close

    Set Destwb = ActiveWorkbook

    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007, we exit the sub when your answer is
            'NO in the security dialog that you only see  when you copy
            'an sheet from a xlsm file with macro's disabled.
            If Sourcewb.Name = .Name Then
                With Application
                    .ScreenUpdating = True
                    .EnableEvents = True
                End With
                MsgBox "Your answer is NO in the securitydialog"
                Exit Sub
            Else
                Select Case Sourcewb.FileFormat
                Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
                Case 52:
                    If .HasVBProject Then
                        FileExtStr = ".xlsm": FileFormatNum = 52
                    Else
                        FileExtStr = ".xlsx": FileFormatNum = 51
                    End If
                Case 56: FileExtStr = ".xls": FileFormatNum = 56
                Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
                End Select
            End If
        End If
    End With

    '    'Change all cells in the worksheets to values if you want
    '    For Each sh In Destwb.Worksheets
    '        sh.Select
    '        With sh.UsedRange
    '            .Cells.Copy
    '            .Cells.PasteSpecial xlPasteValues
    '            .Cells(1).Select
    '        End With
    '        Application.CutCopyMode = False
    '        Destwb.Worksheets(1).Select
    '    Next sh

    'Save the new workbook
    TempFilePath = Application.DefaultFilePath & "\"
    TempFileName = Sourcewb.Name & "-Client"

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, _
                FileFormat:=FileFormatNum
       ' .Close SaveChanges:=False
    End With

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

--

Regards Ron de Bruinhttp://www.rondebruin.nl/tips.htm







- Show quoted text -

Thank you much. Appreciate all your help.