Deleting extra rows in table

[Gail]

I have a table that can be used either in printed form or online. When users
are done entering information online, there are blank rows at the end of the
table that need to be deleted. Can someone please give me a macro that just
deletes blank lines from the table? Thank you. I tried the macros in otehr
postings - and could not get them to work. HELP!

 

[macropod]

Hi Gail,

The following code will delete all blank rows (except for those with vertically merged cells) in all tables in the document:

Sub DelBlankRows()
Dim Pwd As String
Dim oRow As Integer
Dim oTable As Table
Dim pState As Boolean
With ActiveDocument
pState = False
If .ProtectionType <> wdNoProtection Then
Pwd = "Password"
pState = True
.Unprotect Pwd
End If
If .Tables.Count > 0 Then
For Each oTable In .Tables
For oRow = oTable.Rows.Count To 1 Step -1
If Len(Replace(oTable.Rows(oRow).Range.Text, Chr(13) & Chr(7), vbNullString)) = 0 Then
On Error Resume Next 'skip vertically merged cells
oTable.Rows(oRow).Delete
End If
Next oRow
Next oTable
End If
If pState = True Then .Protect wdAllowOnlyFormFields, Noreset:=True, Password:=Pwd
pState = False
Pwd = ""
End With
End Sub

If the document is protected for forms, you'll need to replace "Password" with the real password (if any)

Cheers

--
macropod
[MVP - Microsoft Word]


| I have a table that can be used either in printed form or online. When users
| are done entering information online, there are blank rows at the end of the
| table that need to be deleted. Can someone please give me a macro that just
| deletes blank lines from the table? Thank you. I tried the macros in otehr
| postings - and could not get them to work. HELP!

 

[Gail]

Thank you - it works perfectly!