Dir Function

[Vilem Sova]

I've been battling with the Dir function, to try to get a list of all
subdirectories (including lower subdirectories) within a particular
directory - but without much success.

I'm sure I've seen code somewhere that'll do the trick.

Any help would be appreciated.

Thanks
Vilem Sova

 

[Stefan Hoffmann]

hi Vilem,

I've been battling with the Dir function, to try to get a list of all
subdirectories (including lower subdirectories) within a particular
directory - but without much success.
I'm sure I've seen code somewhere that'll do the trick.

Use Dir("Path", vbDirectory). Executing Dir() subsequently will give you
normal files and folders in "Path".


mfG
--> stefan <--

 

[bob]

Try these resources:
http://www.mvps.org/access/modules/mdl0013.htm
http://www.vba-programmer.com/
Bob

 

[Albert D. Kallal]

Try this code...it will "walk" all sub-dirs for you....


Sub dirTest()

' this code is just to test/show how the sub works...

Dim dlist As New Collection
Dim startDir As String
Dim i As Integer

startDir = "C:\access\"
Call FillDir(startDir, dlist)

MsgBox "there are " & dlist.Count & " in the dir"

' lets printout the stuff into debug window for a test

For i = 1 To dlist.Count
Debug.Print dlist(i)
Next i

End Sub


Sub FillDir(startDir As String, dlist As Collection)

' build up a list of files, and then
' add add to this list, any additinal
' folders

Dim strTemp As String
Dim colFolders As New Collection
Dim vFolderName As Variant

strTemp = Dir(startDir)

Do While strTemp <> ""
dlist.Add startDir & strTemp
strTemp = Dir
Loop

' now build a list of additional folders
strTemp = Dir(startDir & "*.", vbDirectory)

Do While strTemp <> ""
If (strTemp <> ".") And (strTemp <> "..") Then
colFolders.Add strTemp
End If
strTemp = Dir
Loop

' now process each folder (recursion)
For Each vFolderName In colFolders
Call FillDir(startDir & vFolderName & "\", dlist)
Next vFolderName

End Sub