display gridlines

[Steve]

Morning all.
I have multiple worksheets that are displaying the gridlines. This appears
to be fairly common across numerous workbooks, so I'd like to make a macro
that will turn off the display gridlines.
I recorded a macro that turned off the grid lines for a single worksheet,
now I need to put in a for loop to iterate through all of the sheets in the
file.
I tried the following and it hangs up on the "If sh.DisplayGridlines = True
Then" statement, stating it cannot perform this task-- "object does not
support this property or method" a 438 error.
Any ideas on how to make one that does work?
Thank you.

Sub Grids()
'
' grids Macro
' turn off grid lines
'
For Each sh In ActiveWorkbook.Worksheets
If sh.DisplayGridlines = True Then
sh.DisplayGridlines = False

End If
Next
' ActiveWindow.DisplayGridlines = False

End Sub

 

[Joel]

DisplaygridLines is a member of windows not a worksheet

ActiveWorkbook.Windows(1).DisplayGridlines = True

 

[Gary''s Student]

Do not test:

Sub NoGrid()
Dim s As Worksheet
For Each s In Sheets
s.Activate
ActiveWindow.DisplayGridlines = False
Next
End Sub

 

[Steve]

Scaratch my request.
I got it.

Sub Grids()
'The purpose of this macro is to turn off grid lines on all worksheets
' in the file.
For i = 1 To Sheets.Count
With ActiveWindow
If .DisplayGridlines = True Then
.DisplayGridlines = False

End If
End With
Next
' ActiveWindow.DisplayGridlines = False

End Sub

 

[Rick Rothstein]

Try it this way (it will hide the process from the user and keep the current
worksheet active)....

Sub TurnGridLinesOff()
Dim WS As Worksheet, SN As String
Application.ScreenUpdating = False
SN = ActiveSheet.Name
For Each WS In Worksheets
WS.Activate
ActiveWindow.DisplayGridlines = False
Next
Worksheets(SN).Activate
Application.ScreenUpdating = True
End Sub

 

[Steve]

Thanks Rick,
It appears mine didn't work after all..... sigh... one day when I grow up, I
want to know how to program..... whine.......
Yours works......