Display the Highest, Second Highest, Third Highest and so on...

[gkb]

Hi

Can someone help me to find out and place the highest, second highest, third
highest and so on in group of numbers in a sheet?

For example:

QUESTION:
A B C D E F
1004 1004 1004
1518 1517 797
1332 1320 1500
1337 1337 1004
1337 1337 1000
1940 560 1560

I need to find out which is highest, second highest and third highest from
A,B & C and the D, E & F columns should display Highest, Second Highest,
Third Highest accordingly. Where the numbers are equal, i need a display
Equal(AB) or Equal(BC) or Equal (ABC) as the case depends.

I might be overthinking on this, but I am just not getting the right formula.

If someone could please help on this... please

GKB

 

[macropod]

Hi Gary,

On its own, the LARGE() function returns the nth largest value (where n is
the second argument in the function), not the column reference.

Assuming you want the column references in all cases and A1 is your top-left
data row:
In Cell D1, use:
=IF(LARGE($A1:$C1,1)=LARGE($A1:$C1,3),"Equal
(ABC)",IF(LARGE($A1:$C1,1)=LARGE($A1:$C1,2),"Equal
("&CHAR(64+MATCH(LARGE($A1:$C1,1),$A1:$C1,0))&CHAR(64+MATCH(LARGE($A1:$C1,1)
,$A1:$C1,1))&")",CHAR(64+MATCH(LARGE($A1:$C1,1),$A1:$C1,0))))
In Cell E1, use:
=IF(LARGE($A1:$C1,1)=LARGE($A1:$C1,3),"Equal
(ABC)",IF(LARGE($A1:$C1,1)=LARGE($A1:$C1,2),"Equal
("&CHAR(64+MATCH(LARGE($A1:$C1,1),$A1:$C1,0))&CHAR(64+MATCH(LARGE($A1:$C1,1)
,$A1:$C1,1))&")",IF(LARGE($A1:$C1,2)=LARGE($A1:$C1,3),"Equal
("&CHAR(64+MATCH(LARGE($A1:$C1,2),$A1:$C1,0))&CHAR(64+MATCH(LARGE($A1:$C1,3)
,$A1:$C1,1))&")",CHAR(64+MATCH(LARGE($A1:$C1,2),$A1:$C1,0)))))
In Cell F1, use:
=IF(LARGE($A1:$C1,1)=LARGE($A1:$C1,3),"Equal
(ABC)",IF(LARGE($A1:$C1,2)=LARGE($A1:$C1,3),"Equal
("&CHAR(64+MATCH(LARGE($A1:$C1,2),$A1:$C1,0))&CHAR(64+MATCH(LARGE($A1:$C1,3)
,$A1:$C1,1))&")",CHAR(64+MATCH(LARGE($A1:$C1,3),$A1:$C1,0))))
Copy down as far as needed.

Cheers