Excel 2007 ambiguous name detected:Worksheet_Change

[Steved]

Hello from Steved

I'm using excel 2007

I'm getting a
"ambiguous name detected:Worksheet_Change"

What is rquired to do please to have the below macro to work Thankyou.


Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim TimeStr As String

On Error GoTo EndMacro
If Application.Intersect(Target, Range("B2:F500")) Is Nothing Then
Exit Sub
End If
If Target.Cells.Count > 1 Then
Exit Sub
End If
If Target.Value = "" Then
Exit Sub
End If

Application.EnableEvents = False
With Target
If .HasFormula = False Then
Select Case Len(.Value)
Case 1 ' e.g., 1 = 00:01 AM
TimeStr = "00:0" & .Value
Case 2 ' e.g., 12 = 00:12 AM
TimeStr = "00:" & .Value
Case 3 ' e.g., 735 = 7:35 AM
TimeStr = Left(.Value, 1) & ":" & _
Right(.Value, 2)
Case 4 ' e.g., 1234 = 12:34
TimeStr = Left(.Value, 2) & ":" & _
Right(.Value, 2)
Case 5 ' e.g., 12345 = 1:23:45 NOT 12:03:45
TimeStr = Left(.Value, 1) & ":" & _
Mid(.Value, 2, 2) & ":" & Right(.Value, 2)
Case 6 ' e.g., 123456 = 12:34:56
TimeStr = Left(.Value, 2) & ":" & _
Mid(.Value, 3, 2) & ":" & Right(.Value, 2)
Case Else
Err.Raise 0
End Select
.Value = TimeValue(TimeStr)
End If
End With
Application.EnableEvents = True
Exit Sub
EndMacro:
MsgBox "You did not enter a valid time"
Application.EnableEvents = True
End Sub

 

[Jim Thomlinson]

In your sheet code do you have two procedures by the name of
Worksheet_Change
That would be my best guess...

 

[Jim Thomlinson]

I should probably elaborate. In any given code module you can not duplicate a
function or procedure name. I can however have duplicates of the name in
different code modules. When that happens there is a process that your
computer uses to determine which version of the procedure gets run. So for
example in Sheet 1 I can only have one procedure named WorkSheet_Change. In
Sheet 2 I can have another procedure called WorkSheet_Change. Which procedure
is ultimately runs depends on where it is being called from.

 

[Steved]

Hello Jim from Steved

Jim Yes i had 2 ocurrence off "Worksheet_Change" I've deleted one and it is
fine.

Thankyou also for the explanation.