FileOpen with a specific location

[Cooz]

Hi everyone,

How do I - in Word 2003 - show the file open dialog displaying a specified
location, for example the Startup path? The following examples won't work;
the only thing they accomplish is displaying "All files (*.*)" - which they
should.

Sub FileOpenStartUp()
Dim dlgFileOpen As Dialog

Set dlgFileOpen = Application.Dialogs(wdDialogFileOpen)
With dlgFileOpen
.Name = Application.Options.DefaultFilePath(wdStartupPath) &
"\*.*"
.Show
End With
Set dlgFileOpen = Nothing

End Sub

---

Sub FileOpenStartUp()
Dim dlgFileOpen As Dialog
Dim strDocPath As String

strDocPath = Application.Options.DefaultFilePath(wdDocumentsPath)
Application.Options.DefaultFilePath(wdDocumentsPath) =
Application.Options.DefaultFilePath(wdStartupPath)

Set dlgFileOpen = Application.Dialogs(wdDialogFileOpen)
With dlgFileOpen
.Name = "*.*"
.Show
End With
Set dlgFileOpen = Nothing

Application.Options.DefaultFilePath(wdDocumentsPath) = strDocPath
End Sub

---

Sub FileOpenStartUp()
Dim dlgFileOpen As Dialog
Dim strCurrentDir As String

strCurrentDir = CurDir
ChDrive Application.Options.DefaultFilePath(wdStartupPath)
ChDir Application.Options.DefaultFilePath(wdStartupPath)

Set dlgFileOpen = Application.Dialogs(wdDialogFileOpen)
With dlgFileOpen
.Name = "*.*"
.Show
End With
Set dlgFileOpen = Nothing

ChDrive strCurrentDir
ChDir strCurrentDir
End Sub

---

Any help here will be greatly appreciated.

Thank you,
Cooz

 

[Doug Robbins - Word MVP on news.microsoft.com]

Use

Dim fd As FileDialog
Dim Source As Document
Set fd = Application.FileDialog(msoFileDialogFilePicker)
With fd
.AllowMultiSelect = False
.Title = "Select the document that you want to open"
.InitialFileName = Application.StartupPath
If .Show = -1 Then
Set Source = Documents.Open(.SelectedItems(1))
Else
MsgBox "You must select a Form Document."
Exit Sub
End If
End With


--
Hope this helps.

Please reply to the newsgroup unless you wish to avail yourself of my
services on a paid consulting basis.

Doug Robbins - Word MVP, originally posted via msnews.microsoft.com