Find avg & Max for grades

[Param]

I have range (A2:A35) for subject grades (A,B,C,D,E)
What I want to know, it is possible to find avg grade and max grade score by
student?

pls guide me.
TQ

 

[Ardus Petus]

Average: =CHAR(ROUND(AVERAGE(CODE(A2:A35)),0))
Max: =CHAR(MIN(CODE(A2:A35)))

Grades should be UPPERCASE

HTH

 

[Bob Phillips]

The max grade is simple

=CHAR(MIN(IF(B1:B10="Bob",CODE(A1:A10))))

which is an array formula, it should be committed with Ctrl-Shift-Enter, not
just Enter.

Average is harder as what is the avearge of A and B, A, B, A+? I have
assumed down

=CHAR(ROUNDUP(AVERAGE(IF(B1:B10="Bob",MATCH(A1:A10,{"A","B","C","D","E"},0))
),0)+64)

also an array formula

--
HTH

Bob Phillips

(remove nothere from email address if mailing direct)

 

[Ardus Petus]

I forgot to point out these are array formulas, to be validated by
Ctrl+Shift+Enter

 

[Param]

Hi Mr.Ardus Petus,

solution that u provide really help me a lot. but i face new problem when i
enter - or x symbol. Actually i enter grade from range A to E. Beside that i
enter x if the student absent. - for not sitting the paper.
any idea?

 

[Peo Sjoblom]

Something like

=CHAR(ROUND(AVERAGE(IF((CODE(A2:A10)>=65)*(CODE(A2:A10)<=69),CODE(A2:A10))),0))

array entered

--

Regards,

Peo Sjoblom

Northwest Excel Solutions

www.nwexcelsolutions.com

(remove ^^ from email address)

Portland, Oregon

 

[Param]

Hi, thanks for your tips. but i still not understand for what "bob" and why
there is two different range e.g B1:B10 and A1:A10.

my grade all at cell e.g A2:A35. (beside grade A,B,C,D,E there is also
simbol "-" and "x".
I try this:

Average: =CHAR(ROUND(AVERAGE(CODE(A2:A35)),0))
Max: =CHAR(MIN(CODE(A2:A35)))

work fine. But when i enter simbol "-" or "x" it show #value.

Pls show how to overcome this problem. TQ

 

[Param]

Pls I am waiting to know. Anyone pls reply
TQ in advance.