Finding a string of 7 numbers in cell contents

[anon]

Hi,

I have a list of cells, each containing address, tel. no. and customer
ID for a specific customer.

I'm looking to find the customer ID from a each cell and copy to
another cell using vb.

The customer ID could appear at the beginning, middle or end of the
cell contents, however is always 7 digits long with a space at each
side of it (unless it is the first part of the cell contents in which
case there would be no space at the beginning). The complexity is that
the cell also contains telephone numbers, however these are longer
than 7 digits.

Your help / ideas on how I could start tackling this would be much
appreciated. Thanks,

 

[RB Smissaert]

Try something like this:

Sub test()

Dim i As Long
Dim c As Long
Dim n As Long
Dim arr
Dim arr2
Dim arr3

'test data range
arr = Range(Cells(1), Cells(5, 1))

ReDim arr3(1 To UBound(arr), 1 To 1)

For i = 1 To UBound(arr)
arr2 = Split(arr(i, 1), Chr(32))
For c = 0 To UBound(arr2)
If Len(arr2(c)) = 7 Then
If IsNumeric(arr2(c)) Then
n = n + 1
arr3(n, 1) = arr2(c)
End If
End If
Next c
Next i

Range(Cells(3), Cells(UBound(arr), 3)) = arr3

End Sub


RBS

 

[Bernd P]

=regexpreplace(" "&A1&" ","^.* (\d{7}) .*$","$1")

The function regexpreplace you will find here:
http://www.sulprobil.com/html/regexp.html

Regards,
Bernd

 

[Rick Rothstein \(MVP - VB\)]

Your use of this...

If IsNumeric(arr2(c)) Then

could false hit in any number of ways (see my standard warning about
IsNumeric after my signature); for example, one way being if this 123.456
came before this 1234567 in the text. I would do the test this way...

If arr2(c) Like "#######" Then

Rick

From a previous post of mine...

I usually try and steer people away from using IsNumeric to "proof"
supposedly numeric text. Consider this (also see note below):

ReturnValue = IsNumeric("($1,23,,3.4,,,5,,E67$)")

Most people would not expect THAT to return True. IsNumeric has some "flaws"
in what it considers a proper number and what most programmers are looking
for.

I had a short tip published by Pinnacle Publishing in their Visual Basic
Developer magazine that covered some of these flaws. Originally, the tip was
free to view but is now viewable only by subscribers.. Basically, it said
that IsNumeric returned True for things like -- currency symbols being
located in front or in back of the number as shown in my example (also
applies to plus, minus and blanks too); numbers surrounded by parentheses as
shown in my example (some people use these to mark negative numbers);
numbers containing any number of commas before a decimal point as shown in
my example; numbers in scientific notation (a number followed by an upper or
lower case "D" or "E", followed by a number equal to or less than 305 -- the
maximum power of 10 in VB); and Octal/Hexadecimal numbers (&H for
Hexadecimal, &O or just & in front of the number for Octal).

NOTE:
======
In the above example and in the referenced tip, I refer to $ signs and
commas and dots -- these were meant to refer to your currency, thousands
separator and decimal point symbols as defined in your local settings --
substitute your local regional symbols for these if appropriate.

As for your question about checking numbers, here are two functions that I
have posted in the past for similar questions..... one is for digits only
and the other is for "regular" numbers:

Function IsDigitsOnly(Value As String) As Boolean
IsDigitsOnly = Len(Value) > 0 And _
Not Value Like "*[!0-9]*"
End Function

Function IsNumber(ByVal Value As String) As Boolean
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9.]*" And _
Not Value Like "*.*.*" And _
Len(Value) > 0 And Value <> "." And _
Value <> vbNullString
End Function

Here are revisions to the above functions that deal with the local settings
for decimal points (and thousand's separators) that are different than used
in the US (this code works in the US too, of course).

Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
Not Value Like "*" & DP & "*" & DP & "*" And _
Len(Value) > 0 And Value <> DP And _
Value <> vbNullString
End Function

I'm not as concerned by the rejection of entries that include one or more
thousand's separators, but we can handle this if we don't insist on the
thousand's separator being located in the correct positions (in other words,
we'll allow the user to include them for their own purposes... we'll just
tolerate their presence).

Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
Dim TS As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Get local setting for thousand's separator
' and eliminate them. Remove the next two lines
' if you don't want your users being able to
' type in the thousands separator at all.
TS = Mid$(Format$(1000, "#,###"), 2, 1)
Value = Replace$(Value, TS, "")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
Not Value Like "*" & DP & "*" & DP & "*" And _
Len(Value) > 0 And Value <> DP And _
Value <> vbNullString
End Function

 

[RB Smissaert]

Yes, I am aware of all that, but thought it might be OK with the data of the
OP.
You could always do something like this if needed:

If IsNumeric(arr2(c)) Then
If CLng(arr2(c)) = arr2(c) Then
n = n + 1
arr3(n, 1) = arr2(c)
End If
End If

I am sure he will come back if more coding is needed.


RBS

Your use of this...

If IsNumeric(arr2(c)) Then

could false hit in any number of ways (see my standard warning about
IsNumeric after my signature); for example, one way being if this 123.456
came before this 1234567 in the text. I would do the test this way...

If arr2(c) Like "#######" Then

Rick

From a previous post of mine...

I usually try and steer people away from using IsNumeric to "proof"
supposedly numeric text. Consider this (also see note below):

ReturnValue = IsNumeric("($1,23,,3.4,,,5,,E67$)")

Most people would not expect THAT to return True. IsNumeric has some
"flaws" in what it considers a proper number and what most programmers are
looking for.

I had a short tip published by Pinnacle Publishing in their Visual Basic
Developer magazine that covered some of these flaws. Originally, the tip
was free to view but is now viewable only by subscribers.. Basically, it
said that IsNumeric returned True for things like -- currency symbols
being located in front or in back of the number as shown in my example
(also applies to plus, minus and blanks too); numbers surrounded by
parentheses as shown in my example (some people use these to mark negative
numbers); numbers containing any number of commas before a decimal point
as shown in my example; numbers in scientific notation (a number followed
by an upper or lower case "D" or "E", followed by a number equal to or
less than 305 -- the maximum power of 10 in VB); and Octal/Hexadecimal
numbers (&H for Hexadecimal, &O or just & in front of the number for
Octal).

NOTE:
======
In the above example and in the referenced tip, I refer to $ signs and
commas and dots -- these were meant to refer to your currency, thousands
separator and decimal point symbols as defined in your local settings --
substitute your local regional symbols for these if appropriate.

As for your question about checking numbers, here are two functions that I
have posted in the past for similar questions..... one is for digits only
and the other is for "regular" numbers:

Function IsDigitsOnly(Value As String) As Boolean
IsDigitsOnly = Len(Value) > 0 And _
Not Value Like "*[!0-9]*"
End Function

Function IsNumber(ByVal Value As String) As Boolean
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9.]*" And _
Not Value Like "*.*.*" And _
Len(Value) > 0 And Value <> "." And _
Value <> vbNullString
End Function

Here are revisions to the above functions that deal with the local
settings for decimal points (and thousand's separators) that are different
than used in the US (this code works in the US too, of course).

Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
Not Value Like "*" & DP & "*" & DP & "*" And _
Len(Value) > 0 And Value <> DP And _
Value <> vbNullString
End Function

I'm not as concerned by the rejection of entries that include one or more
thousand's separators, but we can handle this if we don't insist on the
thousand's separator being located in the correct positions (in other
words, we'll allow the user to include them for their own purposes...
we'll just tolerate their presence).

Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
Dim TS As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Get local setting for thousand's separator
' and eliminate them. Remove the next two lines
' if you don't want your users being able to
' type in the thousands separator at all.
TS = Mid$(Format$(1000, "#,###"), 2, 1)
Value = Replace$(Value, TS, "")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
Not Value Like "*" & DP & "*" & DP & "*" And _
Len(Value) > 0 And Value <> DP And _
Value <> vbNullString
End Function

Try something like this:

Sub test()

Dim i As Long
Dim c As Long
Dim n As Long
Dim arr
Dim arr2
Dim arr3

'test data range
arr = Range(Cells(1), Cells(5, 1))

ReDim arr3(1 To UBound(arr), 1 To 1)

For i = 1 To UBound(arr)
arr2 = Split(arr(i, 1), Chr(32))
For c = 0 To UBound(arr2)
If Len(arr2(c)) = 7 Then
If IsNumeric(arr2(c)) Then
n = n + 1
arr3(n, 1) = arr2(c)
End If
End If
Next c
Next i

Range(Cells(3), Cells(UBound(arr), 3)) = arr3

End Sub


RBS

 

[Rick Rothstein \(MVP - VB\)]

Yes, I am aware of all that, but thought it might be OK with the data

of the OP.

It probably would be, but why take the chance when the Like comparison is so
easy and foolproof to perform.

You could always do something like this if needed:

If IsNumeric(arr2(c)) Then
If CLng(arr2(c)) = arr2(c) Then

False hits are still possible with this. Off the top of my head...

arr2(c) = "(12345)"

arr2(c) = "$12345$" {substitute regional currency symbol or $}

arr2(c) = "12,3,45"

arr2(c) = "&123456"

Rick

 

[RB Smissaert]

Yes, you are right there. Have tested and all your examples passed the test.
In that case Like "#######" may be the best test. Not sure how fast it is
and
that could be an issue.
How would you test if the number of figures was variable?

RBS

 

[Rick Rothstein \(MVP - VB\)]

Yes, you are right there. Have tested and all your examples passed the

test.
In that case Like "#######" may be the best test. Not sure how fast it is
and that could be an issue.

I'm not sure how Like compares (no pun intended<g>) to IsNumeric speedwise;
but I know it is slower than InStr, so it should not be use in place of that
when testing for substring inclusion within a larger text string.

How would you test if the number of figures was variable?

This will test a number string to see if it is composed of all digits, no
matter how many digits (literally, no matter how many digits; well, up to 2
billion or so digits at least)...

If NumberString Like String(Len(NumberString), "#") Then


Rick

 

[RB Smissaert]

Have compared Like "#######" with IsNumeric etc. and depending on the
supplied value Like can be a lot slower,
I would say about 5 times slower:

Option Explicit
Private lStartTime As Long
Private Declare Function timeGetTime Lib "winmm.dll" () As Long

Sub test()

Dim i As Long
Dim v
Dim b As Boolean

'v = 1234567
'v = "1234567"
v = Cells(1)

StartSW
For i = 0 To 100000
b = IsDigitsOnly(v)
Next i
StopSW

MsgBox b

End Sub

Function IsDigitsOnly(v As Variant) As Boolean

IsDigitsOnly = v Like String(Len(v), "#")

End Function

Function IsDigitsOnly2(v As Variant) As Boolean

If IsNumeric(v) Then
If CLng(v) = v Then
IsDigitsOnly2 = True
End If
End If

End Function

Sub StartSW()
lStartTime = timeGetTime()
End Sub

Function StopSW(Optional bMsgBox As Boolean = True, _
Optional vMessage As Variant, _
Optional lMinimumTimeToShow As Long = -1) As Variant

Dim lTime As Long

lTime = timeGetTime() - lStartTime

If lTime > lMinimumTimeToShow Then
If IsMissing(vMessage) Then
StopSW = lTime
Else
StopSW = lTime & " - " & vMessage
End If
End If

If bMsgBox Then
If lTime > lMinimumTimeToShow Then
MsgBox "Done in " & lTime & " msecs", , vMessage
End If
End If

End Function


But if the test value is supplied like this: "1234567" then Like is faster.
Probably speed doesn't come into it for the OP, so I take Like will be best.


RBS

 

[Ron Rosenfeld]

Hi,

I have a list of cells, each containing address, tel. no. and customer
ID for a specific customer.

I'm looking to find the customer ID from a each cell and copy to
another cell using vb.

The customer ID could appear at the beginning, middle or end of the
cell contents, however is always 7 digits long with a space at each
side of it (unless it is the first part of the cell contents in which
case there would be no space at the beginning). The complexity is that
the cell also contains telephone numbers, however these are longer
than 7 digits.

Your help / ideas on how I could start tackling this would be much
appreciated. Thanks,

Place the UDF

=CustomerID(cell_ref)

in the destination cell.

Place the code below in a regular module:

================================
Option Explicit
Function CustomerID(str) As String
Dim re As Object, mc As Object
Set re = CreateObject("vbscript.regexp")
re.Pattern = "\b\d{7}\b"

If re.test(str) = True Then
Set mc = re.Execute(str)
CustomerID = mc(0).Value
End If
End Function
===============================
--ron