Finding the lowest number

[Barney]

In cell A4, I want to check cell A3, to see if it is the sole lowest number
in a set of numbers. The set is not a range but rather individual cells like
A3, A5, A7, A9, A11, A13 etc. If the number (A3) is the lowest and has no
others equal to it in the set, then I want to put the number 1 in cell A4.

What is the formula for cell A4?

Thanks,

Barney

 

[francis]

try this
=IF(A3<=MIN(A3,A5,A7,A9),1,"")

--
Hope this is helpful

Pls click the Yes button below if this post provide answer you have asked


Thank You

cheers, francis

 

[Barney]

That doesn't solve the problem of A3 being the SOLE number of that value in
the set.

Thanks,

Barney

 

[Bob Phillips]

=SUMPRODUCT(--(MOD(ROW($A$3:$A$13),2)=1),--($A$3:$A$13=$A$3))=1

 

[Shane Devenshire]

Hi,

You haven't told us what you want A4 to display if the number in A3 is not
the sole smallest number. I am going to assume, you want it to display
nothing. Also, you say the numbers are in A3, A5, A7 I am assuming that
pattern, every other row continues. Question, you say the range is A3,
A5,... and then you want the formula put in the same column as the numbers?
this will cause a circular reference for many solutions. You also say that
the formula should check the content of A3, so you want to compare A3 with
A3, A5, A7,...?

I am putting this formula in B1 and checking to see if the minimum number in
the range only occurs once:

=IF(SUM(--(MIN(IF(MOD(ROW(A3:A10),2)*A3:A10>0,MOD(ROW(A3:A10),2)*A3:A10))=MOD(ROW(A3:A10),2)*A3:A10))=1,1,"")

This is an array formula so you must press Shift+Ctrl+Enter to enter it.

 

[T. Valko]

=SUMPRODUCT(--(MOD(ROW($A$3:$A$13),2)=1),--($A$3:$A$13=$A$3))=1

Using these values:

1,0,3,4,5,6

That formula returns TRUE.

Maybe this if the range isn't any bigger:

=(A3=MIN(A3,A5,A7,A9,A11,A13))*(A3<>SMALL((A3,A5,A7,A9,A11,A13),2))

 

[Trent S]

For the formula in A4, couldn't you just use:
=--(A3<MIN(A5,A6,A7,A8,A9,A10))

 

[T. Valko]

Yeah, that'll work. Just use the correct range.

=--(A3<MIN(A5,A7,A9,A11,A13))

 

[Barney]

Yes, this worked. Thanks for the help.

Barney