Why not run the macro to add the \ to the text before the user starts typing
the footnote text? That way, you can do it with one macro.
===========================
Sub FootnoteMacro()
Dim fn As Footnote
Dim sRef As Style
' Set the options for footnotes.
Selection.FootnoteOptions.Location = wdBottomOfPage
Selection.FootnoteOptions.NumberingRule = wdRestartContinuous
Selection.FootnoteOptions.StartingNumber = 1
Selection.FootnoteOptions.NumberStyle = wdNoteNumberStyleArabic
' Set the style for footnotes in the text.
Set sRef = ActiveDocument.Styles("Footnote Reference")
sRef.Font.Underline = wdUnderlineSingle
' Insert the footnote.
Set fn = Selection.Footnotes.Add(Range:=Selection.Range)
' Add the \ to the footnote in the text.
fn.Reference.Select
Selection.Collapse Direction:=wdCollapseEnd
Selection.Style = sRef
' Selection.Font.Underline = wdUnderlineNone ' This line ensures that the
\ is not underlined.
Selection.TypeText Text:="\"
' Add the \ to the footnote at the bottom.
fn.Range.Select
Selection.MoveLeft Unit:=wdCharacter, Count:=1
Selection.Style = sRef
' Selection.Font.Underline = wdUnderlineNone ' This line ensures that the
\ is not underlined.
Selection.TypeText Text:="\"
' Move the cursor to be ready to accept the footnote text.
Selection.Collapse Direction:=wdCollapseEnd
Selection.MoveStart Unit:=wdCharacter, Count:=1
End Sub
===========================
Note that you might want to remove / adjust the part where the Footnote
Reference style is manipulated and the options are set.
If you name the macro "InsertFootnoteNow", you can even make it take over
the default functionality of the "Insert Footnote" button on the References
tab.
Yves
I have some users who insist their footnote numbers be superscripted,
underlined, and followed by a superscripted diagonal. I can get the
underlining by changing the style and can get the diagonal in the note
itself with a macro, but can’t figure a way to get the diagonal after
the number in the text without going back to it after typing the
footnote and running another macro. Is there an easier way to
accomplish this? Thanks.
