forms with pull-down list

[Loui]

Is there any way to run a macro that will update the names
in drop-down form field in a form?

I have a fax form with a drop-down field that provides the
various names of people in the firm. If changes are made
in personnel, I want to be able to NOT JUST change the
master form, but be able to update the list if the user
brings up a fax form that they SAVED.

Loui

 

[Doug Robbins - Word MVP]

Hi Loui,

Not with formfields.

If you were to use a userform in your template, you could have a combobox or
listbox on that form populated with data from an external source whenever
the form is used so that any changes to the data in the external source
would be reflected in subsequent use of the form.

This routine loads a listbox with client details stored in a table in a
separate
document (which makes it easy to maintain with additions, deletions etc.),
that document being saved as Clients.Doc for the following code.

On the UserForm, have a list box (ListBox1) and a Command Button
(CommandButton1) and use the following code in the UserForm_Initialize() and
the CommandButton1_Click() routines

Private Sub UserForm_Initialize()
Dim sourcedoc As Document, i As Integer, j As Integer, myitem As Range,
m As Long, n As Long
' Modify the path in the following line so that it matches where you
saved Suppliers.doc
Application.ScreenUpdating = False
' Open the file containing the client details
Set sourcedoc = Documents.Open(FileName:="e:\worddocs\Clients.doc")
' Get the number or clients = number of rows in the table of client
details less one
i = sourcedoc.Tables(1).Rows.Count - 1
' Get the number of columns in the table of client details
j = sourcedoc.Tables(1).Columns.Count
' Set the number of columns in the Listbox to match
' the number of columns in the table of client details
ListBox1.ColumnCount = j
' Define an array to be loaded with the client data
Dim MyArray() As Variant
'Load client data into MyArray
ReDim MyArray(i, j)
For n = 0 To j - 1
For m = 0 To i - 1
Set myitem = sourcedoc.Tables(1).Cell(m + 2, n + 1).Range
myitem.End = myitem.End - 1
MyArray(m, n) = myitem.Text
Next m
Next n
' Load data into ListBox1
ListBox1.List() = MyArray
' Close the file containing the client details
sourcedoc.Close SaveChanges:=wdDoNotSaveChanges
End Sub

Private Sub CommandButton1_Click()
Dim i As Integer, Addressee As String
Addressee = ""
For i = 1 To ListBox1.ColumnCount
ListBox1.BoundColumn = i
Addressee = Addressee & ListBox1.Value & vbCr
Next i
ActiveDocument.Bookmarks("Addressee").Range.InsertAfter Addressee
UserForm2.Hide
End Sub

The Initialize statement will populate the listbox with the data from the
table and then when a client is selected in from the list and the command
button is clicked, the information for that client will be inserted into a
bookmark in the document. You may want to vary the manner in which it is
inserted to suit our exact requirements, but hopefully this will get you
started.

To make it easy for you, the code has been written so that it will deal with
any number of clients and any number of details about each client. It
assumes that the first row of the table containing the client details is a
header row.

Please post any further questions or followup to the newsgroups for the
benefit of others who may be interested. Unsolicited questions forwarded
directly to me will only be answered on a paid consulting basis.

Hope this helps
Doug Robbins - Word MVP

 

[Mark Tangard]

Hi Loui & Doug,

Well, there *is* a way to do it with formfields. It's not terribly
pretty but it seems to worK. Create -- and update as needed -- a
text file named Personnel.INI, and store it in a network location
accessible to all users. (Substitute its path for "N:\Path" below.)
Then use the following as the On Entry macro to the dropdown field:

Sub PopulateAddresseeDropdown()
Dim nextguy As String
If Dir$("N:\Path\Personnel.INI") = "" Then
MsgBox "Personnel list not found."
Exit Sub
End If
With ActiveDocument.FormFields("Addressee").DropDown
.ListEntries.Clear
Open "N:\Path\Personnel.INI" For Input As #1
Do While Not EOF(1)
Input #1, nextguy
.ListEntries.Add nextguy
Loop
Close #1
.Value = 1
End With
End Sub