formual, match G19 from G2:g17 return corresponding A2:A17

[ref at heart]

A2:A17 is a list of names on a team
G19 is a "=LARGE(G2:G17,1)" formula and then second and third highest
What I would like to do is get the corresponding name to match up with the
large 1 number
I've tried many, closets is =lookup(G19,G2:G17,A2:A17)
All this does is give me the name in A17
help please

 

[The Code Cage Team]

The Lookup as you have used it there gives the correct answer for th
largest number found in G2:G17!, i don't understand what it is you ar
trying to achieve?

A2:A17 is a list of names on a team
G19 is a "=LARGE(G2:G17,1)" formula and then second and third highest
What I would like to do is get the corresponding name to match up wit
the
large 1 number
I've tried many, closets is =lookup(G19,G2:G17,A2:A17)
All this does is give me the name in A17
help pleas

--
The Code Cage Tea

Regards,
The Code Cage Team
'The Code Cage' (http://www.thecodecage.com

 

[Dave Peterson]

=index(a2:a17,match(large(g2:g17,1),g2:g17,0))

max(g2:g17)
instead of:
large(g2:g17,1)
would work for the largest match, too.

 

[ref at heart]

Thank you Dave,
Works perfect
Question, what is the 0 for?

 

[ref at heart]

Follow problem
I am using the large 1,2,3 for first, second and third place
In one of these equations I have a duplicate number "622"
Which is a tie between first and second
It's using the same person for first and second
How to I get it to pick up the other name associated to 622?

thanks ~ you guys are awesome on this site!

 

[Dave Peterson]

0 (or False) means that it has to be an exact match.

 

[Dave Peterson]

I'm sure someone will be coming along with a solution.

 

[T. Valko]

Assume you want the results to appear starting in cell J2.

Enter this array formula** in J2 and copy down to J17:

=INDEX(A$2:A$17,MATCH(LARGE(G$2:G$17-ROW(G$2:G$17)/10^10,ROWS(J$2:J2)),G$2:G$17-ROW(G$2:G$17)/10^10,0))

** array formulas need to be entered using the key combination of
CTRL,SHIFT,ENTER (not just ENTER). Hold down both the CTRL key and the SHIFT
key then hit ENTER.