formula for excel sheet.

[BVG]

Hi,
I want to use a formula in excel as below described.

i want a formula value in Cell A2.b In Cell A1 is value say if it is $ 500
or above then the A2 should be 75% of A1, if A2 is between 200 to 500 then
A2 should be 50%, if A1 is below 200 then A2 should be 25% of A1, so please
help me out - thanks in advance.

 

[Ms-Exl-Learner]

Paste this formula in A2 cell

=IF(AND(A1>=0,A1<200),A1*25/100,IF(AND(A1>=200,A1<500),A1*50/100,IF(A1>=500,A1*75/100,"")))

Remember to Click Yes, if this post helps!

 

[Fred Smith]

=if(a1>500,a1*75%,if(a1>200,a1*50%,a1*25%))

Regards,
Fred

 

[Arvi Laanemets]

Hi

When values in A1 never will be negative or non-numeric, then
=MATCH($A$1,{0;200;500},1)*0.25

When values in A1 may be negative, but the condition 'below 200' applies,
then
=MATCH($A$1,{-999999;200;500},1)*0.25
(replace the 1st member in array (-999999) with any of your own.

When values in A1 < 0 must return an empty cell or some string, then
=IF(ISERROR(MATCH($A$1,{0;200;500},1)),"",MATCH($A$1,{0;200;500},1)*0.25)


Arvi Laanemets

 

[Arvi Laanemets]

Another solution:

=0.25*(($A$1>=0)+($A$1>=200)+($A$1>=500))

When no condition applies, this formula returna 0%

PS: In both answers, format the formula cell as percentage!


Arvi Laanemets

 

[David Biddulph]

.... but having tested for A1<200 you don't then need to test for A1>=200,
and similarly for 500.

=IF(AND(A1>=0,A1<200),A1*25/100,IF(AND(A1>=200,A1<500),A1*50/100,IF(A1>=500,A1*75/100,"")))
can be simplified to
=IF(A1<0,"",IF(A1<200,A1*25%,IF(A1<500,A1*50%,A1*75%)))