Formula is too long

[Mike]

For better assistance with your problem, post the formula
you are trying to use. There may be a way to reduce the
size of the formula using better syntax or different
functions. You may need to split your formula apart into
more columns. Or you might try using Named Ranges instead
of hard coded ranges. Here are a few ideas that may help
you, but without knowing what you are trying to do I'm
limited to what I can use for samples.

For an example of better syntax, consider something like
this:
=IF(ISERROR(INDEX(Sheet1!B:B,MATCH(A1,Sheet1!
A:A,0))),"",INDEX(Sheet1!B:B,MATCH(A1,Sheet1!A:A,0)))

In the above example, there is a rundundant function used
in the error check that you could remove. Since the Match
is what may cause the error, not the Index, remove the
Index to get a slightly smaller formula that does the same
thing (and faster I may add):
=IF(ISERROR(MATCH(A1,Sheet1!A:A,0)),"",INDEX(Sheet1!
B:B,MATCH(A1,Sheet1!A:A,0)))

I'll also use the above to demonstrate splitting the
formula apart. You'll notice the Match function is
duplicated twice. So pull it out into it's own column.
This reduces the whole mass by quite a bit, and again,
speeds up calculations.
B1=MATCH(A1,Sheet1!A:A,0)
C1=IF(ISERROR(B1),"",INDEX(Sheet1!B:B,B1))

And finally to use Named Ranges instead of hard coded
ranges. Select column A in Sheet1 and enter a name in the
name box (to the left of the formula bar), let's use
SaleDate as an example. And do the same for column B, and
call it SaleQty. In addition to reducing the formula size
a bit, it also makes the formula more easy to understand.
B1=MATCH(A1,SaleDate,0)
C1=IF(ISERROR(B1),"",INDEX(SaleQty,B1))