Formula Simplification Please ...

[Ken]

Excel2003 ... The following formula works, but I am thinking it can be
simplified by those intimate with Excel ...

=IF(AND($F$3="Y",C12=1),(D12/8)*(5/7),IF(AND($F$3="Y",C12=2),(D12/16)*(5/7),IF(AND($F$3="Y",C12=3),(D12/21.5)*(5/7),IF(AND($F$3="N",C12=1),D12/8,IF(AND($F$3="N",C12=2),D12/16,IF(AND($F$3="N",C12=3),D12/21.5,""))))))

Thanks ... Kha

 

[Jacob Skaria]

Try this using IF() and CHOOSE().. Sorry i could not test this..

=IF(F3="Y",D12/CHOOSE(C12,8,16,21.5)*(5/7),IF(F3="N",D12/CHOOSE(C12,8,16,21.5)))

If this post helps click Yes

 

[Ken]

Jacob ... (Hi)

This formula worked fine until D12 value got small ... then it returned the
#VALUE error ... ???

Thanks ... I am always learning ... Kha

 

[Ken]

Jacob ... (Hi)

Sorry ... it was when the C12 Value (not D12) got small ... <1.00

Thanks ... Kha

 

[Jacob Skaria]

Sorry have you specified a condition for values <1 for c12

=IF(C12<1,"",IF(F3="Y",D12/CHOOSE(C12,8,16,21.5)*(5/7),IF(F3="N",D12/CHOOSE(C12,8,16,21.5))))

If this post helps click Yes

 

[Teethless mama]

Try this:

=IF(OR(C12<1,C12>3),"",D12/CHOOSE(C12,8,16,21.5)*IF(F3="Y",5/7,1))

 

[Ken]

Jacob ... (Good morning)

Oversight on my part ... In my original post I requested options for
conditions 1-2-3 ... I forgot I had some default entries in Col C set @ .01
.... so when I copied your formula down it failed @ the point in Range where
Col C had an entry <1.00 ... I changed my default from .01 to 1 ... So now my
options in Col C are truly 1-2-3 (as they should be).

Above said ... Your original formula now works fine & is a great
simplification ...

Every day is a learning experience ... Just some days I forget more than I
learn.

Thanks ... Kha