Generate date on Semi-Monthly Basis

[debinnyc]

I am using Excel 2003 and trying to determine a formula to generate the next
date on a semi monthly basis. For example, I have a cell for next pay date,
which when filled in I want the other cells to automatically generate the
next pay date accurately. If I enter 4/15/2008 as my next paydate, then I
want the other cells to readout 4/30/2008, 5/15/2008, 5/31/2008, etc. Any
help would be greatly appreciated. Thanks!

 

[David Biddulph]

How do you define your pay days? Are they always the 15th and the last day
of the month?
If so, try
=IF(DAY(A1)=15,DATE(YEAR(A1),MONTH(A1)+1,0),DATE(YEAR(A1),MONTH(A1)+1,15))

 

[Mike H]

Hi,

Put your start day in A1 and the in A2 and drag down

=IF(DAY(A1)=15,EOMONTH(A1,0),DATE(YEAR(A1),MONTH(A1)+1,15))

Mike

 

[Fred Smith]

Try:

a1 = 4/15/2008
a2 =date(year(a1),month(a1)+1,if(day(a1)=15,0,15))

Regards,
Fred

 

[Kevin B]

The ffollowing formula will do the trick:

=IF(DAY(G1)=15,DATE(YEAR(G1),MONTH(G1)+1,1)-1,DATE(YEAR(G1),MONTH(G1)+1,15))

 

[Mike H]

I should have added if you get a name error then

Tools|Addins
and check the analysis toolpack

Mike