How to rename default Outlook XP folders?

[LL]

I found no article/info/discussion on my issue on Microsoft site or
elsewhere, so here it goes:
I wish to find out a way to rename the default Outlook XP mail folders
created by the software in the system (ie, not user created folders). Namely,
they are the "Inbox", "Sent Items", "Deleted Items" etc.
This is because of many reasons. We bought Traditional Chinese versions of
Office XP. By default, the folders are named in Traditional Chinese. Even if
we apply the multilangual pack to change the interface to English, these
special folders are not renamed to English.
In addition, since we have some custom programs that need to work under the
Simplified Chinese mode, we have to adjust our computer so that for non
unicode characters, they will be displayed in Simplified Chinese by Windows.
Doing so render these folder names in Traditional Chinese displayed
incorrectly. The text/characters become corrupted non sense form of Chinese.
The users get confused with the folder names as a result, and just want to
have them named in English.
Is there a registry entry or somewhere I can do this? Being in Hong Kong, we
are one of the many companies that have offices around the world with
different kinds of languages used in daily activities. As such I hope
Microsoft can give us a solution.
Thank yoU!

 

[neo [mvp outlook]]

The folders can be renamed programmatically. Here is a vbscript file that
gives you an idea on how to rename one folder at a time.

' RenFldr - Rename Outlook "Special Folders"
' (c) Neo ([email protected])
' 11.11.2000, v.1.0
' 11.06.2002, v.1.1

' Test System
' Windows Script Host v.
' VBScript v.
' Outlook 2000 (SR1a)
' Windows 2000 (SP1)

' Change Log
' 11.11.2000 - Creation Date
' 11.06.2002 - Added support drafts folder

Const olFolderDeletedItems = 3
Const olFolderOutbox = 4
Const olFolderSentItems = 5
Const olFolderInbox = 6
Const olFolderCalendar = 9
Const olFolderContacts = 10
Const olFolderJournal = 11
Const olFolderNotes = 12
Const olFolderTasks = 13
Const olFolderDrafts = 16

Dim Engine
Dim Outlook
Dim Folder

Select Case UCase(Right(WScript.FullName, 11))
Case "WSCRIPT.EXE"
Engine = "W"
Case "CSCRIPT.EXE"
Engine = "C"
End Select

Set Args = WScript.Arguments

If Args.Count = 0 Then
DisplayHelp()
WScript.Quit
End If

If Args.Item(0) = "-?" Or Args.Item(0) = "/?" Or Args.item(0) = "?" Then
DisplayHelp()
WScript.Quit
End If

If Args.Count <> 2 Then
DisplayHelp()
WScript.Quit
End If

Set Outlook = CreateObject("Outlook.Application")
Set Folder = Nothing

Select Case UCase(Args.Item(0))
Case "CALENDAR"
Set Folder =
Outlook.GetNameSpace("MAPI").GetDefaultFolder(olFolderCalendar)
Case "INBOX"
Set Folder = Outlook.GetNameSpace("MAPI").GetDefaultFolder(olFolderInbox)
Case "OUTBOX"
Set Folder = Outlook.GetNameSpace("MAPI").GetDefaultFolder(olFolderOutbox)
Case "SENTITEMS"
Set Folder =
Outlook.GetNameSpace("MAPI").GetDefaultFolder(olFolderSentItems)
Case "DELETEDITEMS"
Set Folder =
Outlook.GetNameSpace("MAPI").GetDefaultFolder(olFolderDeletedItems)
Case "CONTACTS"
Set Folder =
Outlook.GetNameSpace("MAPI").GetDefaultFolder(olFolderContacts)
Case "JOURNAL"
Set Folder =
Outlook.GetNameSpace("MAPI").GetDefaultFolder(olFolderJournal)
Case "NOTES"
Set Folder = Outlook.GetNameSpace("MAPI").GetDefaultFolder(olFolderNotes)
Case "TASKS"
Set Folder = Outlook.GetNameSpace("MAPI").GetDefaultFolder(olFolderTasks)
Case "DRAFTS"
Set Folder =
Outlook.GetNameSpace("MAPI").GetDefaultFolder(olFolderDrafts)
Case Else
DisplayHelp()
End Select

If Folder Is Nothing Then
WScript.Quit
End If

Folder.Name = Args.Item(1)

Set Folder = Nothing
Set Outlook = Nothing

Sub DisplayHelp()
If Engine = "W" Then
MsgBox "RenFldr:" & vbCRLF &_
" Change Name of Default Folders" & vbCRLF & vbCRLF &_
"Usage: RenFldr Folder NewName" & vbCRLF & vbCRLF &_
" Supported values for Folder:" & vbCRLF &_
" Inbox" & vbCRLF &_
" Outbox" & vbCRLF &_
" Calendar" & vbCRLF &_
" SentItems" & vbCRLF &_
" DeletedItems" & vbCRLF &_
" Contacts" & vbCRLF &_
" Journal" & vbCRLF &_
" Notes" & vbCRLF &_
" Tasks" & vbCRLF &_
" Drafts"
Else
WScript.StdOut.WriteLine "RenFldr:"
WScript.StdOut.WriteLine " Change Name of Default Folders" & vbCRLF
WScript.StdOut.WriteLine "Usage: RenFldr Folder NewName" & vbCRLF
WScript.StdOut.WriteLine " Supported values for Folder:"
WScript.StdOut.WriteLine " Inbox"
WScript.StdOut.WriteLine " Outbox"
WScript.StdOut.WriteLine " Calendar"
WScript.StdOut.WriteLine " SentItems"
WScript.StdOut.WriteLine " DeletedItems"
WScript.StdOut.WriteLine " Contacts"
WScript.StdOut.WriteLine " Journal"
WScript.StdOut.WriteLine " Notes"
WScript.StdOut.WriteLine " Tasks"
WScript.StdOut.WriteLine " Drafts"
End If
End Sub

 

[LL]

Thank you, it worked after I made some adjustments. For the computer dummies
reading this thread, here's what I did to make it work:

I copied and pasted the program code enclosed to a test file and named it
xyz.vbs. I concatenated the lines that end with
Set Folder
with
lines that begin with
= Outlook.GetNameSpace

I then run this script in command prompt, specifying the parameters (eg,
Inbox Inbox) to tell it rename the Inbox folder as Inbox.

 

[LL]

So, would there also be a similar solution for Outlook Express? It seems
there isn't (at least, i think outlook express does not run macros).
I do noticed, that besides the folder names like inbox, sentitems, there is
still an object name called 'personal folder' (shown next to the 'outlook
today'). can we rename it too, as it is also affected by the corruption in
text due to language change

 

[Brian Tillman]

So, would there also be a similar solution for Outlook Express? It
seems there isn't (at least, i think outlook express does not run
macros).
I do noticed, that besides the folder names like inbox, sentitems,
there is still an object name called 'personal folder' (shown next to
the 'outlook today'). can we rename it too, as it is also affected by
the corruption in text due to language change

You can certainly rename your Personal Folders file in any way you want.
Right-click Outlook Today and choose Properties, then Advanced. Change the
"Name" field to be whatever you want. That's the name that is displayed in
the Folder List view of the Navigation Pane.