How to set Auto-Change letters into Uppercases for Data entry in E

[Cpviv]

Hi,

I need help here.

Here is the scenario.
When I type alphabets in lower cases at each cell, I need the cell to
auto-change the alphabets to upper cases. I do not want to use the Caps Lock
button from the keyboard.

Help...

 

[Mike H]

Hi,

Right click your sheet tab, view code and paste this in. It works on the
entire sheet so if you want it limited to a certain range then post back

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Cells.Count > 1 Or IsEmpty(Target) Then Exit Sub
If Not IsNumeric(Target) Then
Application.EnableEvents = False
Target = UCase(Target)
Application.EnableEvents = True
End If
End Sub

Mike

 

[Cpviv]

Hi Mike,

It works!

Ok, you are right. I have many columns fill with data. How to set one column
with Uppercases, one column with Propercases, one column with the first
letter starts with Capital letter, and the rest of columns leave as they are.

Cpviv

 

[Mike H]

Hi,

This is set up to work on columns 1,2 & 3 for Upper Proper and Lower cases

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Cells.Count > 1 Or IsEmpty(Target) Then Exit Sub
If Not IsNumeric(Target) Then
Application.EnableEvents = False
If Target.Column = 1 Then 'Column A
Target = StrConv(Target, vbUpperCase)
ElseIf Target.Column = 2 Then
Target = StrConv(Target, vbProperCase)
ElseIf Target.Column = 3 Then
Target = StrConv(Target, vbLowerCase)
End If
Application.EnableEvents = True
End If
End Sub

Mike