Hyperlink macro for personal.xls

[al007]

Sub Hyperlinkcell()
'
Dim actual As Range

Set actual = Application.InputBox(Prompt:="Select cell to
hyperlink.", Type:=8)
ActiveSheet.Hyperlinks.Add Anchor:=Selection, Address:="",
SubAddress:=actual, TextToDisplay:=ActiveCell.Value
End Sub

Can anybody fix the above hyperlink macro pls.

Thxs

 

[Norman Jones]

Hi Al007,

Try:

'=============>>
Public Hyperlinkcell()
Dim actual As Range

Set actual = Application. _
InputBox(Prompt:="Select cell to hyperlink.", _
Type:=8)
'

ActiveSheet.Hyperlinks.Add _
Anchor:=Selection, _
Address:="", _
SubAddress:=actual.Address(0, 0)
End Sub
'<<=============

 

[al007]

Thxs - but it does not work if a cell from a different sheet is
selected - can you help pls

 

[Tom Ogilvy]

Sub Hyperlinkcell()
'
Dim actual As Range

Set actual = Application.InputBox( _
Prompt:="Select cell to hyperlink.", Type:=8)
ActiveSheet.Hyperlinks.Add _
Anchor:=Selection, _
Address:="", _
SubAddress:="'" & actual.Parent.Name & _
"'!" & actual.Address(0, 0), _
TextToDisplay:=actual.Text
End Sub

 

[Tom Ogilvy]

Here is a slight revision

Sub Hyperlinkcell()
'
Dim actual As Range
Dim Act_Cell as Range
set Act_Cell = ActiveCell
Set actual = Application.InputBox( _
Prompt:="Select cell to hyperlink.", Type:=8)
ActiveSheet.Hyperlinks.Add _
Anchor:=Act_Cell, _
Address:="", _
SubAddress:="'" & actual.Parent.Name & _
"'!" & actual.Address(0, 0), _
TextToDisplay:=actual.Parent.Name & _
"!" & actual.Address(0, 0)
End Sub