I am trying to figure out how to add per 1000

[DG]

It starts out at a flat fee of $316.25 for everything from 0 to $55,000.00,
and then adds $5.75 per $1,000.00 up to a maximum of $100,000 and then
anything over $100,000 the rate drops to $5.00 per $1,000 up to 1 million.

What I am attempting to do is place a number like $250,000 in a box and have
excel do the equation and automatically place $1,325.00 in another box.

 

[Govind]

Hi,

If your number of $250,000 is placed in cell A1, paste this formula in
cell B1

=IF(A1<55000,316.25,IF(A1<100000,316.25+(5.75*(ROUND(A1-55000,-3)/1000)),(316.25+5.75*((100000-55000)/1000)+5*(ROUND(A1-100000,-3)/1000))))

Note that the formula rounds off the variance to nearest thousand.

Regards

Govind.

 

[DG]

You are a life saver!!!!!
Thanks!

Hi,

If your number of $250,000 is placed in cell A1, paste this formula in
cell B1

=IF(A1<55000,316.25,IF(A1<100000,316.25+(5.75*(ROUND(A1-55000,-3)/1000)),(316.25+5.75*((100000-55000)/1000)+5*(ROUND(A1-100000,-3)/1000))))

Note that the formula rounds off the variance to nearest thousand.

Regards

Govind.

 

[Dana DeLouis]

What I am attempting to do is place a number like $250,000 in a box and

have
excel do the equation and automatically place $1,325.00 in another box.

Hi. If you do not wish to RoundUp your value per $1,000 as in your example,
another option might be:

=MAX(316.25,MIN(75+A1/200,(23*A1)/4000))

Returns $1325 also.
HTH :>)

 

[Robert_Steel]

A different approach
=SUM(--(A1>0)*316.25,--(A1>55000)*(INT(A1/1000-55)*5.75),--(A1>100000)*(INT(A1/1000-100)*-0.75))

personal preference as to which you choose. This would be neater if you
wish to increase the number of price brackets.
hth RES

 

[Ashish Mathur]

Hi,

i worked on a similar problem some time back. May be this helps. The
datain the table is something like this (Range B28):

Income slab Rate

- 0%
50,000.00 10%
150,000.00 20%
320,000.00 30%
600,000.00 40%

The total taxable income i sentered in cell D10.

In cell C12, array enter the following formula (Ctrl+Shift+Enter)

=SUM(IF($D$10<B4:B8,0,IF(B5:B9-B4:B8>$D$10,$D$10-B4:B8,IF(B5:B9-B4:B8>0,IF(B5:B9-B4:B8>$D$10-B4:B8,$D$10-B4:B8,B5:B9-B4:B8),$D$10-B4:B8)))*(C4:C8))

Regards,

Ashish Mathur