Identifing Weeks in a Month.

[GEM]

I have this function,

=TEXT(TODAY()-WEEKDAY(NOW(),3),"mmmm d, yyyy")&" -
"&TEXT(TODAY()-WEEKDAY(NOW(),3)+6,"mmmm d, yyyy")

It identifies the week we are currently in starting on Monday by giving me
the result "July 27, 2009 - August 2, 2009"

How can I insert a function on different cells which give me the first,
second, third, and forth week of the month?? For example for this month,

A1=June 29, 2009 - July 5, 2009
A2=July 6, 2009 - July 12, 2009
A3=July 13, 2009 - July 19, 2009
A4= July 20, 2009 - July 26, 2009
A5=July 27, 2009 - August 2, 2009

 

[barry houdini]

How do you define the "first" week of the month? In your example Jun
29th clearly starts in the previous month, but presumably week 1 o
August starts on 3rd August, is there a rule

 

[GEM]

Thank you Barry,

I want to start on a Monday, if the first day of the month starts on a
friday, I would like to identify the monday right before that friday first of
the month. For example this month, the 1st of July started on a Wednesday, so
I would like to start on Monday June 29th. And the last day of July will be
on a Friday, so I would like it to end on Sunday August 2nd, because they are
complete weeks from Monday - Sunday.

Did I get my message throught??

 

[Teethless mama]

In A1: =TODAY()

In B1:
=TEXT(DATE(YEAR($A$1),MONTH($A$1),(ROWS($1:1)-1)*7+1)-WEEKDAY(DATE(YEAR($A$1),MONTH($A$1),(ROWS($1:1)-1)*7+1))+2,"mmmm
dd, yyyy")&" -
"&TEXT(DATE(YEAR($A$1),MONTH($A$1),(ROWS($1:1)-1)*7+1)-WEEKDAY(DATE(YEAR($A$1),MONTH($A$1),(ROWS($1:1)-1)*7+1))+8,"mmmm dd, yyyy")

copy from B1 down

The result will be:

June 29, 2009 - July 05, 2009
July 06, 2009 - July 12, 2009
July 13, 2009 - July 19, 2009
July 20, 2009 - July 26, 2009
July 27, 2009 - August 02, 2009

 

[Ron Rosenfeld]

I have this function,

=TEXT(TODAY()-WEEKDAY(NOW(),3),"mmmm d, yyyy")&" -
"&TEXT(TODAY()-WEEKDAY(NOW(),3)+6,"mmmm d, yyyy")

It identifies the week we are currently in starting on Monday by giving me
the result "July 27, 2009 - August 2, 2009"

How can I insert a function on different cells which give me the first,
second, third, and forth week of the month?? For example for this month,

A1=June 29, 2009 - July 5, 2009
A2=July 6, 2009 - July 12, 2009
A3=July 13, 2009 - July 19, 2009
A4= July 20, 2009 - July 26, 2009
A5=July 27, 2009 - August 2, 2009

A1:
=TEXT(TODAY()+7*(ROWS($1:1)-1)-DAY(TODAY())-
WEEKDAY(TODAY()-DAY(TODAY())-2),"mmmm d, yyyy - ")
& TEXT(TODAY()+7*(ROWS($1:1)-1)+6-DAY(TODAY())-
WEEKDAY(TODAY()-DAY(TODAY())-2),"mmmm d, yyyy")

and fill down through A5
--ron