Importing data from a database (Excel or Access) into Word documen

[kiwi]

Hi there. I am a novice user of all these programs really.

I work as a physiotherapist assessing injured peoples workplaces before they
return to work. After each assessment I will write a report and perhaps send
a fax or two, maybe write a letter to a doctor etc. For each client I may
write between 4-8 documents over a number of weeks. I spend a fair bit of
time cutting and pasting basic details such as name and address details, case
manager details, claim numbers etc into the various documents.

Could I please be pointed in the right direction to learn how to make this
task easier. Is it possible to set up an initial database for each client,
and then set up word templates whereby if I want to write a certain type of
report it will automatically import the details I want from the database into
the appropriate places of a word template?

I have had people suggest either Access or Excell as the initial program for
holding the original data, and then somehow merging the data needed into
templates. Where can I learn how to do this? How do I do this?

Any advice would be greatly appreciaited.

Thanks, Ben

 

[Suzanne S. Barnhill]

Although I am not familiar with Access, I believe it is capable of providing
"reports" in a wide variety of formats (including your letters and faxes).
It might make more sense to do the whole job in Access.

 

[Doug Robbins - Word MVP]

What you want to do is certainly possible, but there will be a bit of
programming involved.

Firstly, you should create a template for each of the standard types of
reports/letters/faxes that you may create, and in that template, set up a
userform - See the article "How to create a Userform" at:

http://word.mvps.org/FAQs/Userforms/CreateAUserForm.htm

Then if you have entered the data into a table in an Access database, the
following code can be used to populate a listbox or combobox on the userform
with all of the records from the table so that when you select a record, you
can have the information from that record inserted into controls on the
userform where you can manually enter in any other details that you may wish
and then have the information inserted into the relevant parts of the
document that you are creating:

Private Sub UserForm_Initialize()
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim NoOfRecords As Long
' Open the database
Set db = OpenDatabase("D:\Access\ResidencesXP.mdb")
' Retrieve the recordset
Set rs = db.OpenRecordset("SELECT * FROM Owners")
' Determine the number of retrieved records
With rs
.MoveLast
NoOfRecords = .RecordCount
.MoveFirst
End With
' Set the number of Columns = number of Fields in recordset
ListBox1.ColumnCount = rs.Fields.Count
' Load the ListBox with the retrieved records
ListBox1.Column = rs.GetRows(NoOfRecords)
' Cleanup
rs.Close
db.Close
Set rs = Nothing
Set db = Nothing
End Sub

As an alternative, the data for each patient could be entered into a table
in a Word document (one patient to a row) and then a routine similar to the
following could be used to populate a list box or combobox on a userform
with the data so that you could select the patient for whom you want to
create the document

This routine loads a listbox with client details stored in a table in a
separate
document (which makes it easy to maintain with additions, deletions etc.),
that document being saved as Clients.Doc for the following code.

On the UserForm, have a list box (ListBox1) and a Command Button
(CommandButton1) and use the following code in the UserForm_Initialize() and
the CommandButton1_Click() routines

Private Sub UserForm_Initialize()
Dim sourcedoc As Document, i As Integer, j As Integer, myitem As Range,
m As Long, n As Long
' Modify the path in the following line so that it matches where you
saved Clients.doc
Application.ScreenUpdating = False
' Open the file containing the client details
Set sourcedoc = Documents.Open(FileName:="e:\worddocs\Clients.doc")
' Get the number or clients = number of rows in the table of client
details less one
i = sourcedoc.Tables(1).Rows.Count - 1
' Get the number of columns in the table of client details
j = sourcedoc.Tables(1).Columns.Count
' Set the number of columns in the Listbox to match
' the number of columns in the table of client details
ListBox1.ColumnCount = j
' Define an array to be loaded with the client data
Dim MyArray() As Variant
'Load client data into MyArray
ReDim MyArray(i, j)
For n = 0 To j - 1
For m = 0 To i - 1
Set myitem = sourcedoc.Tables(1).Cell(m + 2, n + 1).Range
myitem.End = myitem.End - 1
MyArray(m, n) = myitem.Text
Next m
Next n
' Load data into ListBox1
ListBox1.List() = MyArray
' Close the file containing the client details
sourcedoc.Close SaveChanges:=wdDoNotSaveChanges
End Sub

Private Sub CommandButton1_Click()
Dim i As Integer, Addressee As String
Addressee = ""
For i = 1 To ListBox1.ColumnCount
ListBox1.BoundColumn = i
Addressee = Addressee & ListBox1.Value & vbCr
Next i
ActiveDocument.Bookmarks("Addressee").Range.InsertAfter Addressee
UserForm2.Hide
End Sub

The Initialize statement will populate the listbox with the data from the
table and then when a client is selected in from the list and the command
button is clicked, the information for that client will be inserted into a
bookmark in the document. You may want to vary the manner in which it is
inserted to suit our exact requirements, but hopefully this will get you
started.

To make it easy for you, the code has been written so that it will deal with
any number of clients and any number of details about each client. It
assumes that the first row of the table containing the client details is a
header row.

--
Hope this helps.

Please reply to the newsgroup unless you wish to avail yourself of my
services on a paid consulting basis.

Doug Robbins - Word MVP

 

[kiwi]

Hi Doug and Suzzane.

Thanks so much for the reply Doug. I need to mull throught that I think.
Good to know it is possible.

Greatly appreciated. I will contact you if specific info needed etc.

Thanks again,

Ben