Lotus/Excel questions

[noni1]

In Lotus Release 5, I have a large spreadsheet with 25 worksheets set up
under the Global Group command. This allows me to work in a particular cell
and hit Ctrl & Page Up to go from one worksheet to another in that same cell.
Will Excel 2003 perform this same function? I know you can highlight the
tabs and can go to the same cell on each worksheet, but if you change
something in a cell it is reflected in all cells. I need to be able to make
changes in the individual cells, without it affecting the individual
worksheet.

Any suggestions?

 

[Billy Liddel]

Ctrl PGUP PGDN will work but not retain the same cell; Excel returns to the
last selected cell in the sheet.

To get the effect you want you will need a macro for each way. The macros
can be assigned shortcut keys in the Macro, Options say Ctrl + r and Ctrl + c

Sub GoNext()
Dim Addr As String
Dim i As Integer

Addr = ActiveCell.Address
i = ActiveSheet.Index

If i = Worksheets.Count Then
Exit Sub
Else
Application.Goto Worksheets(i + 1).Range(Addr)
End If

End Sub

Sub GoPrev()
Dim Addr As String
Dim i As Integer

Addr = ActiveCell.Address
i = ActiveSheet.Index

If i = 1 Then
Exit Sub
Else
Application.Goto Worksheets(i - 1).Range(Addr)
End If

End Sub

To Insert the macro in the current workbook press ALT + F11, Insert, Module
and copy the code into the module and return to the worksheet.

Press ALT + F8 to bring up the Macros form select the first macro and click
the Option button and assign the shortcut letter (It can not be PGUP). enter
a brief dscription and the shortcut keys Ctrl + Letter) Be careful not to use
one that Excel uses S,F,G,P etc.

Done this way the macros will only be available in the current workbook. To
make it available in all books they should be saved in your Personal workbook.

If you do not have one already then open a blank workbook and record a macro
while you do something simple. Save the file as Personal. Both macros are
then available in all workbooks.

Note: it you migrate to xl2007 your macros will no longer be available in
xl2003.

HTH
Peter