Macro to insert an object in a specific cell 2007`

[mpsears62]

I am trying to insert an object in a specific cell. i can get it to work in
2003, but not in 2007 does anyone have any insight as to what i am doing
wrong....here is the code that i am using

Sub test()
'
' test Macro
' Macro recorded 7/7/2008 by mspears
'

'
Range("B30").select
ActiveSheet.Pictures.Insert("H:\scan0002.jpg").Select
Selection.ShapeRange.PictureFormat.TransparentBackground = msoTrue
Selection.ShapeRange.PictureFormat.TransparencyColor = RGB(253, 253, 253)
Selection.ShapeRange.Fill.Visible = msoFalse
Application.CommandBars("Picture").Visible = False
End Sub

 

[Dave Peterson]

From what I've read, xl2007 doesn't play nice with .select's with objects like
pictures.

Option Explicit
Sub test()
Dim myPict As Picture
With ActiveSheet
Set myPict = .Pictures.Insert("H:\scan0002.jpg")
End With

With myPict
.Top = .Parent.Range("B30").Top
.Left = .Parent.Range("b30").Left
.ShapeRange.PictureFormat.TransparentBackground = msoTrue
.ShapeRange.PictureFormat.TransparencyColor = RGB(253, 253, 253)
.ShapeRange.Fill.Visible = msoFalse
End With
End Sub

Should work in both xl2007 and earlier versions.

 

[mpsears62]

Thank you so very much.. i really appreciate the help...