Making tables accessible in MS Word Forms Options

[calebm12]

Have a challenge i cant seem to figure out. I am making a form that i
want to lock down, only allowing the user to enter text into the form
fields. However, part of the document consists of a table where they
will enter info into a cell then move on to another cell. The problem
is, depending on how much entries they have they might need to add
another row or two to the table. How can i allow this. I know
without a form lockdown all they would have to do is push tab and a
new row would appear. However this is not happening with a locked
form. How can i format the table to allow this??

 

[Doug Robbins - Word MVP]

You will need to insert formfields into the cells of the table and set the
following macro to run on exit from the last cell of the table

Sub addRow()

' Macro created 02/02/03 by Doug Robbins
' To add a new row to a table containing formfields in every column
' automatically on exit from the last cell in the present last row of the
table
Dim rownum As Long, i As Long
Dim Response
Response = MsgBox("Do you need to add another row to the table?", vbYesNo +
vbQuestion + vbDefaultButton2, "Add another Row")
If Response = vbYes Then ' User chose Yes.
With ActiveDocument
.Unprotect
With Selection.Tables(1)
.Rows.Add
rownum = .Rows.Count
For i = 1 To .Columns.Count
ActiveDocument.FormFields.Add Range:=.Cell(rownum, i).Range,
Type:=wdFieldFormTextInput
Next i
.Cell(.Rows.Count, .Columns.Count).Range.FormFields(1).ExitMacro
= "addRow"
.Cell(.Rows.Count, 1).Range.FormFields(1).Select
End With
.Protect Type:=wdAllowOnlyFormFields, NoReset:=True
End With
Else ' User chose No.
Exit Sub
End If

End Sub



--
Hope this helps.

Please reply to the newsgroup unless you wish to avail yourself of my
services on a paid consulting basis.

Doug Robbins - Word MVP