match value in array and display 2 or more results

[jC!]

hi all,

i would like to lookup a value in column A, which might produce two or
more results from column B

an example

Column A (Date) Column B (Task Completed)
11/12/2003 Task 01
13/12/2003 Task 02
10/12/2003 Task 03
10/12/2003 Task 04
11/12/2003 Task 05
14/12/2003 Task 06
10/12/2003 Task 07

now i would like to create a list to display all the tasks completed
on the 10/12/2003
Task 03
Task 04
Task 07

the value (10/12/2003) i will change at will, the length of the array
for lookup data and result data will vary

i presume this would have to be entered as an array, but that is the
extend of my knowledge - if anybody could provide some hints or
direction as to what Worksheet Functions to use, this would be mostly
appreciated.

cheers....

.....jurgenC!

 

[Harlan Grove]

...
...

Column A (Date) Column B (Task Completed)
11/12/2003 Task 01
13/12/2003 Task 02
10/12/2003 Task 03
10/12/2003 Task 04
11/12/2003 Task 05
14/12/2003 Task 06
10/12/2003 Task 07

now i would like to create a list to display all the tasks completed
on the 10/12/2003
Task 03
Task 04
Task 07

the value (10/12/2003) i will change at will, the length of the array
for lookup data and result data will vary

...

If the table above were in A2:B8 and your date entry were in cell D2, then in F2
enter the formula

=IF(COUNTIF($A$2:$A$8,$D$2),VLOOKUP($D$2,$A$2:$B$8,2,0),"")

and in cell F3 enter the *array* formula

=IF(COUNTA(F$2:F2)<COUNTIF($A$2:$A$8,$D$2),INDEX($B$2:$B$8,
SMALL(IF($A$2:$A$8=$D$2,ROW($A$2:$A$8)-CELL("Row",$A$2:$A$8)+1),
ROW()-ROW($F$2)+1)),"")

Select F3 and fill down into F4:F8.

 

[jC!]

hi Harlan,

very nice - thanks a million!

have a great day on your side of the screen.

cheers....


....jurgenC!