Multiple AND OR functions

[Woodi2]

Is it possible to make this function work?

=IF(AND(AND($B9="Z",AE9=35),OR(J9=1,J9="M",J9="C")),1000,IF(AND(AND($B9="A+",AE9=35),OR(J9=1,J9="M",J9="C")),750))

I need to find out if Cell B9 = Z and if Cell AE9 = 35, if this true then
check cell J9 and check if it equals 1, M or C then return the value as 1000.
(that bit works OK)
I also want it to check if an alternative statement is true if the first is
false whereby it checks the the same set of cells but this time, check if B9
=A+, if Cell AE9 = 35, if this true then check cell J9 and check if it equals
1, M or C then return the value as 750. I can get each function to work
individually but dont know how to combine it into one function.

 

[Jacob Skaria]

Try the below...

=IF(AND($B9="Z",AE9=35),IF(OR(J9=1,J9="M",J9="C"),1000,""),
IF(AND($B9="A+",AE9=35),IF(OR(J9=1,J9="M",J9="C"),750,""),""))

 

[Sean Timmons]

The formula below works fine. Are you looking for there to be a value if both
are false?

=IF(AND(AND($B9="Z",AE9=35),OR(J9=1,J9="M",J9="C")),1000,IF(AND(AND($B9="A+",AE9=35),OR(J9=1,J9="M",J9="C")),750,0))

Would make it 0 if False...

 

[Steve Dunn]

There are simpler ways of stating your formula, but it currently does as
described. What your formula does not do, and you do not describe, is what
you want to happen when neither condition is true. Before we attempt to
simplify it, you need to clarify that.

 

[Steve Dunn]

One possibility:

=IF(AND(AE9=35,OR(J9=1,J9="M",J9="C")),IF(B9="Z", 1000, IF(B9="A+",750,0)))

 

[Steve Dunn]

Another possibility:

=(AE9=35)*((J9=1)+(J9="M")+(J9="C"))*((B9="Z")*1000+(B9="A+")*750)