multiple > < and = question

[TR Young]

I am trying to return certain values if certain criteria are met. Here is my
function, and I will break it down to make this easier to understand:

=IF(D55>0,IF(E17=1,IF(D13<36.344,1,IF(D13>=36.344,OR(IF(D13<39.549,2,IF(D13=>39.549,3,0)))))),0)

First, this cell will only display if D55>0, hence
=IF(D55>0,

Next, if cell E17=1 AND if D13<36.344, then I want a value of 1 returned.
IF(D13<36.344,1

BUT... (still assuming that E17=1) if D13>=36.344 or D13<39.549, I want a
value of 2 returned.
IF(D13>=36.344,OR(IF(D13<39.549,2

and lastly (and still assuming that E17=1), if D13=>39.549, I want a value
of 3 returned.
IF(D13>=39.549,3

And to close out the function...
,0)))))),0)

What I am getting with this current function is that if I type a number in
D13 that is < 36.344, I get a correct value of 1 returned. However, if I
have a number that is => 36.344 in D13, all I get is a "True" value returned
and I can't figure out why.

Please forgive me if this is not possible; I am pretty new at TRYING to
understand multiple function Excel programming, and being an old BASIC
programmer seems to be a detriment....

 

[Teethless mama]

Try this:

=IF(AND(D55>0,E17=1,D13<36.344),1,IF(OR(D13>=36.344,D13<39.549),2,IF(D13>=39.549,3,0)))

 

[TR Young]

Ok, that is one step closer, however it is not returning a value of 3 if
D13=>39.549.
I really appreciate the help so far!

 

[PCLIVE]

I think this needs to be an AND statement, not OR.
OR(D13>=36.344,D13<39.549)

Try this.

=IF(AND(D55>0,E17=1,D13<36.344),1,IF(AND(D13>=36.344,D13<39.549),2,IF(D13>=39.549,3,0)))

Regards,
Paul

 

[David Biddulph]

Try =IF(D55>0,IF(E17=1,IF(D13<36.344,1,IF(D13<39.549,2,3)),0),0)

I assume you want it to return 0 if D55<=0, or if E17<>1?

You said:
"> Next, if cell E17=1 AND if D13<36.344, then I want a value of 1 returned.

IF(D13<36.344,1

BUT... (still assuming that E17=1) if D13>=36.344 or D13<39.549, I want a
value of 2 returned."

but in that case if you haven't satisfied the test for D13<36.344 then it
must satify the test for D13>=36.344, so I assume that you nean AND
D13<39.549, rather than OR D13<39.549?

 

[David Biddulph]

Try =IF(D55>0,IF(E17=1,IF(D13<36.344,1,IF(D13<39.549,2,3)),0),0)

I assume you want it to return 0 if D55<=0, or if E17<>1?

You said:
"> Next, if cell E17=1 AND if D13<36.344, then I want a value of 1 returned.

IF(D13<36.344,1

BUT... (still assuming that E17=1) if D13>=36.344 or D13<39.549, I want a
value of 2 returned."

but in that case if you haven't satisfied the test for D13<36.344 then it
must satify the test for D13>=36.344, so I assume that you nean AND
D13<39.549, rather than OR D13<39.549?

 

[TR Young]

Ok, I got it!! Thanks for all the help!