My mail merge for labels will only update the first 3 labels

[Kelcy]

When using 2007 mail merge for labels I follow the wizard and insert the
address block, but when I go and hit update all it only shows the first 3
labels on the page, and the last 2. The labels seem to be updated, as
multiple pages show up and the recipients at the end of my data source
correspond to the last labels on the last page, but there must be a gap
somewhere from being merged to showing up on the page. Please Help!

 

[Doug Robbins - Word MVP]

There is a bug with that facility when using a Tablet PC (and sometimes a
non-Tablet PC that has some "tablet-like" functionality available). Here is
a macro that overcomes the problem.

Macro to overcome the problem with propagation of mail merge field fields
with a label type mail merge when using a Tablet PC and some other Computers
that have Tablet PC Functionality available:

Sub MailMergePropagateLabel()

Dim atable As Table

Dim i As Long, j As Long

Dim source As Cell, target As Cell

Dim myrange As Range

Set atable = ActiveDocument.Tables(1)

Set source = atable.Cell(1, 1)

Set myrange = source.Range

myrange.Collapse wdCollapseStart

ActiveDocument.Fields.Add Range:=myrange, Text:="NEXT", _

PreserveFormatting:=False

source.Range.Copy

For j = 2 To atable.Columns.Count

Set target = atable.Cell(1, j)

If target.Range.Fields.Count > 0 Then

target.Range.Paste

End If

Next j

For i = 2 To atable.Rows.Count

For j = 1 To atable.Columns.Count

Set target = atable.Cell(i, j)

If target.Range.Fields.Count > 0 Then

target.Range.Paste

End If

Next j

Next i

atable.Cell(1, 1).Range.Fields(1).Delete

End Sub



It is suggested that you put this code into a template that you save in the
Word Startup folder so that it becomes an add-in and will be available
whenever you need it. As the macro has the same name as the Word Command
that is supposed to do the job, this macro will run when the Update Labels
button is used when setting up the mail merge label main document.

If you do not know what to do with the code, see the article "What do I do
with macros sent to me by other newsgroup readers to help me out?" at:

http://www.word.mvps.org/FAQs/MacrosVBA/CreateAMacro.htm



--
Hope this helps.


Please reply to the newsgroup unless you wish to avail yourself of my
services on a paid consulting basis.

Doug Robbins - Word MVP

 

[Kelcy]

I input the macro, but when I have it run, an error pops up that says
"expected: input" maybe I'm inputting the macro wrong?

 

[Doug Robbins - Word MVP]

Did you have the mail merge main document open at the time that you ran it?
If you save the template containing the macro as an add-in, the macro will
run automatically when you click on the Update Labels button.

--
Hope this helps.

Please reply to the newsgroup unless you wish to avail yourself of my
services on a paid consulting basis.

Doug Robbins - Word MVP