Need help with formula and functions =AVERAGE

[greyhwk]

I am building a testing chart for equipment.
I have 5 tests on each item and have to put in their numerical value.
I need to average the values dropping the highest and lowest values as
sometimes the values can be a misread of the test equipment.

The question is, is ther are formula, argument or function that can be as
follows:
=AVERAGE (C1:F1) ignore =MIN(C1:F1) and =MAX(C1:F1)

I have been looking through the help built in to Excel and have not had
success in finding the answer.

greyhwk

 

[Peo Sjoblom]

A couple of ways

=TRIMMEAN(C1:F1,2/COUNT(C1:F1))

or

=(SUM(C1:F1)-MAX(C1:F1)-MIN(C1:F1))/(COUNT(C1:F1)-2)

regards,

Peo Sjoblom

 

[Bernie Deitrick]

greyhwk,

=(Sum(C1:F1)-Min(C1:F1)-Max(C1:F1))/(Count(C1:F1)-2)

HTH,
Bernie

 

[David Hager]

First of all, C1:F1 contains only 4 values<g>.

Hold down the Ctrl and Shift when entering the following formula.

=AVERAGE(LARGE(B1:F1,{2,3,4}))

Regards,
David Hager
Excel FMVP

 

[Bernie Deitrick]

David and Peo,

That's three of us FMVPs answering one question! - These slow news servers
really are a drag.

Take care - hopfully, we'll all be back sometime soon.

Bernie

 

[2rrs]

I am building a testing chart for equipment.
I have 5 tests on each item and have to put in their numerical value.
I need to average the values dropping the highest and lowest values as
sometimes the values can be a misread of the test equipment.

The question is, is ther are formula, argument or function that can be as
follows:
=AVERAGE (C1:F1) ignore =MIN(C1:F1) and =MAX(C1:F1)

I have been looking through the help built in to Excel and have not had
success in finding the answer.

greyhwk

Give this a try.

=-(AVERAGE(C1:F1)-MAX(C1:F1)-MIN(C1:F1))