I've just switched to Entourage X (sr1) from Outlook 2000 on Win2K.
I'd like to know if I can change the due date for multiple tasks in
one step.
For instance I have 5 tasks falling due on Friday and I'd like to
change the due date for all 5 to Monday in one go.
In Outlook 2000 I could create a custom view which grouped tasks by
due date, then drag a selection of tasks from the Friday date group
into the Monday date group - changing the due date to Monday for all
selected tasks.
Currently I find myself having to open each task individually set the
due date and close the task window.
There doesn't appear to be a grouping facility of any kind.
You can use a custom view to find them but you can't apply a single change
in one fell swoop like that. It sounds nifty.
You can run an AppleScript in Script Editor that will do it, after making
your selection in the Tasks List:
tell application "Microsoft Entourage"
activate
set selectedTasks to the selection
repeat with theTask in selectedTasks
if class of theTask is task then set due date of theTask to date
"19 Jan 2004"
end repeat
end tell
Edit as needed. Or alter it slightly so that you can use it on future
occasions, and save it (call it
Change Due Date \cmD
which will let you call it from a keyboard shortcut control-command-D, or
from the Script menu.
Save it as a Script to the Entourage Script Menu Items folder in the
~/Documents/Microsoft User Data folder.:
-----------------------------------------------
tell application "Microsoft Entourage"
activate
open main window -- brings it to front
try
set dispArea to displayed area of main window
if dispArea is not tasks area then error number -128
on error
beep 2
display dialog "You must first select some tasks in the Tasks List."
buttons {"OK"} default button 1 with icon 0
return
end try
try
set selectedTasks to the selection
on error
beep 2
display dialog "You must first select some tasks in the Tasks List."
buttons {"OK"} default button 1 with icon 0
return
end try
set done to false
repeat until done
display dialog "Enter a date in your own date format to be the due
date of all currently selected tasks in the Tasks List:" default answer ""
with icon 1
set dueDateString to (text returned of result)
if dueDateString = "" then
beep
display dialog "You must fill in a date in your own date
format." with icon 2
else
try
tell me to set dueDate to date dueDateString
set done to true
on error
beep
try -- works in Panther
set shortToday to "e.g. " & short date string of
(current date)
on error
set shortToday to ""
end try
display dialog "You must fill in a date in your own date
format." & return & return & shortToday with icon 2
end try
end if
end repeat
repeat with theTask in selectedTasks
set due date of theTask to dueDate
end repeat
display dialog "Done!" buttons {"OK"} default button 1 with icon 1
giving up after 3
end tell
----------------------------------------------------------
After yoiu have saved this to the correct folder, you can run it by
selecting its name in the Script menu (the S-squigly thing next to the Help)
or by pressing control-command-D (or read in the Help: AppleScript how to
set your own keyboard shortcut).
Likewise I don't seem to be able to sort by more than one criteria in
any view. Is there any way that I can sort my task list by category
then by due date they by priority for instance?
Nope. Outlook is much more advanced in that regard. If you download my free
"Print Tasks List" script from
MacScripter.net <
http://macscripter.net/scriptbuilders/>
you can set the Tasks list to display in a Word Table (you don't actually
have to print it) with secondary and even tertiary sorting, as in Outlook.
There are various options for better display as well (such as having No Due
Date tasks at the bottom, not the top, etc.), various table formats, and so
on. Again, you can run it from teh Script menu whenever you want.
--
Paul Berkowitz
MVP Entourage
Entourage FAQ Page: <
http://www.entourage.mvps.org/toc.html>
AppleScripts for Entourage: <
http://macscripter.net/scriptbuilders/>
Please "Reply To Newsgroup" to reply to this message. Emails will be
ignored.
PLEASE always state which version of Entourage you are using - 2001 or X.
It's often impossible to answer your questions otherwise.
