Numbering Copies in Watermark

[BalaMukh]

Hi all

I want to print 50 copies of a document and add a watermark on each copy
giving it an individual, sequential number from 1-50. Can I do this in one
operation without having to change the number (in the text of the watermark)
of each copy and print it individually?

TIA

 

[Shauna Kelly]

Hi

The only way I know to do this is to use a macro that inserts your watermark
and changes the text for each copy.

If you don't know what to do with the macro below, see
http://www.gmayor.com/installing_macro.htm

Option Explicit

Sub Print50Documents()
'Shauna Kelly for
'microsoft.public.word.numbering
'9 January 2005

Dim oShape As Word.Shape
Dim nCounter As Long
Dim sMyMessage As String
Dim nHowManyCopies As Long
Dim nLeft As Long
Dim nTop As Long
Dim bPrintOut As Boolean

'Change the following to suit your needs
sMyMessage = "Copy Number "
nLeft = 75
nTop = 450

'Change the following to say
'50 when you're confident
'it will work
nHowManyCopies = 2

'Change the following to True to
'actually print. Leave it at
'False to test.
bPrintOut = False


ActiveWindow.ActivePane.View.SeekView = _
wdSeekCurrentPageHeader
With Selection
Set oShape = .HeaderFooter.Shapes.AddTextEffect _
(PresetTextEffect:=msoTextEffect2, _
Text:=sMyMessage & Str(nCounter), _
FontName:="Arial", _
FontSize:=1, _
FontBold:=False, _
FontItalic:=False, _
Left:=nLeft, _
Top:=nTop)

With oShape
.TextEffect.NormalizedHeight = False
.Line.Visible = False
With .Fill
.Visible = True
.Solid
.ForeColor.RGB = RGB(100, 100, 100)
.Transparency = 0.5
End With
.Rotation = 315
.LockAspectRatio = True
.Height = CentimetersToPoints(2)
.Width = CentimetersToPoints(15)
End With

End With

For nCounter = 1 To nHowManyCopies
oShape.TextEffect.Text = _
sMyMessage & Str(nCounter)
If bPrintOut Then
ActiveDocument.PrintOut
End If
Next nCounter

End Sub



Hope this helps.

Shauna Kelly. Microsoft MVP.
http://www.shaunakelly.com/word