Hi Jana,
Here's the macro I told you about. Each module has plenty of comments to
explain what's going on.
Option Explicit
Dim TrkStatus As Boolean ' Track Changes flag
Private Sub AutoOpen()
' This routine runs whenever the document is opened.
' It calls on the others to do the real work.
' Prepare the environment.
Call MacroEntry
' Most of the work is done by this routine.
Call UpdateFields
' Set the saved status of the document to true, so that changes via
' this code are ignored. Since the same changes will be made the
' next time the document is opened, saving them doesn't matter.
ActiveDocument.Saved = True
' Go to the start of the document
Selection.HomeKey Unit:=wdStory
' Clean up and exit.
Call MacroExit
End Sub
Private Sub MacroEntry()
' Store current Track Changes status, then switch off temporarily.
With ActiveDocument
TrkStatus = .TrackRevisions
.TrackRevisions = False
End With
' Turn Off Screen Updating temporarily.
Application.ScreenUpdating = False
End Sub
Private Sub MacroExit()
' Restore original Track Changes status
ActiveDocument.TrackRevisions = TrkStatus
' Restore Screen Updating
Application.ScreenUpdating = True
End Sub
Private Sub UpdateFields()
' This routine sets the new path for external links.
Dim oRange As Word.Range
Dim oField As Word.Field
Dim OldPath As String
Dim NewPath As String
' Set the new path
NewPath = Replace$(ActiveDocument.Path, "\", "\\")
' Go through all story ranges in the document, including shapes,
' headers & footers.
For Each oRange In ActiveDocument.StoryRanges
' Go through the fields in the story range.
For Each oField In oRange.Fields
With oField
' Skip over fields that don't have links to external files
If Not .LinkFormat Is Nothing Then
' Get the old path
OldPath = Replace(.LinkFormat.SourcePath, "\", "\\")
' Replace the link to the external file
.Code.Text = Replace(.Code.Text, OldPath, NewPath)
End If
End With
Next oField
Next oRange
End Sub
Cheers
--
macropod
[MVP - Microsoft Word]
"(e-mail address removed)"
I would love to have the macro information. I will most likely be receiving
these documents, adjusting them and then saving them into the correct folder.
The macro would be of great help.
Thanks for everything.
Jana
macropod said:
Hi Jana,
Set up a document that you'll use to import the content into (your target
document). Set up your page numbering convention in that. Then you can use a
series of INCLUDETEXT fields to import all or part of each of your source
documents, in whatever order you like.
Note that it's important that any formatting styles are used consistently
throughout, because any that exist in the target document will override any
differences in usage in the source documents.
The other point to note is that, if you change the location of the source
documents, you'll have to update the target document's links to them. This
is especially likely to occur if you send the set to your clients and they
put them into folders with any differences in path names to what you're
using. If you and they will always keep the source and target documents in
the same folder, whatever the path, I can provide a macro to automatically
update the links whenever the target document is opened.
Cheers
--
macropod
[MVP - Microsoft Word]
"(e-mail address removed)"
I have two generate a rather large document that will be collaborated between
several firms. I would like to be able to have the page numbering continue
between several documents. Is there a way to either make a book out
of
these
documents or bind them in some sort of way so I don't have to go in a change
the starting page number on each document whenever there might be a slight
change in the page amounts.
I do have a publishing program that does this, but since my clients do not
have the program, I am using Word to generate this document.
Any help would be greatly appreciated.
Jana
