Daiya Mitchell said:
Word's auto-numbered captions use SEQ (sequence) fields, and you can add a
switch to tell it to restart numbering.
The Help topic "Field codes: Seq (Sequence) field" says that the "\r" switch
"Resets the sequence number to the specified number n. For example, { SEQ
figure \r 3 } starts figure numbering at 3."
To add the switch, control-click (or right-click) the field, select Toggle
Field Codes, and just type it in, then toggle field codes back off.
If you do this frequently, you can use something like this (which I
excerpted from an old project - it therefore could undoubtedly use some
redesign and error handling to be more robust):
Public Sub RenumberCaptions()
Const sCAPTION As String = "Figure"
Const s1 As String = " SEQ "
Const s2 As String = " \* ARABIC "
Const sPrompt As String = " captions start with:"
Const sInputBoxTitle As String = "Renumber Captions"
Const nDefaultStart As Long = 1
Dim vStart As Variant
Dim i As Long
Dim sFirstCaption As String
Dim sOtherCaptions As String
Dim sTest As String
Dim bNotFirst As Boolean
With ActiveDocument.Fields
If .Count > 0 Then
Do
vStart = InputBox( _
Prompt:=sCAPTION & sPrompt, _
Title:=sInputBoxTitle, _
Default:=nDefaultStart)
If Not IsNumeric(vStart) Then Exit Sub
Loop Until vStart >= 1
sFirstCaption = s1 & sCAPTION & " \r " & _
CLng(vStart) & s2
sOtherCaptions = s1 & sCAPTION & s2
sTest = s1 & sCAPTION & "*"
For i = 1 To .Count
With .Item(i).Code
If .Text Like sTest Then
If bNotFirst Then
.Text = sOtherCaptions
Else
.Text = sFirstCaption
bNotFirst = True
End If
End If
End With
Next i
If bNotFirst Then .Update
End If
End With
End Sub
