John Holt said:
I have purchased a 19 inch CRT and use 1280x1024 resolution, which is a tad
small for my eyes I regularly set the zoom to 110% which makes all fine.
I have to do this everytime I open an excel file, can I have Excel remember
this setting.
Yes.
You can set the zoom for all *new* workbooks by creating a new workbook,
setting the sheet(s) Zoom property to 110% and saving the file *as a
template* named Workbook (no extension) in the Microsoft Office
N:Office:Startup folder.
You can also set each window's zoom property when opening either a new
file or an old file:
If you use Personal Macro Workbook, put this code in that file,
otherwise put it in an add-in:
In a regular code module:
Public clsZoom As Zoom
In the ThisWorkbook code module:
Private Sub Workbook_Open()
Set clsZoom = New Zoom
End Sub
In a class module, named Zoom
Public WithEvents oApp As Application
Private Sub Class_Initialize()
Set oApp = Excel.Application
End Sub
Private Sub oApp_NewWorkbook(ByVal Wb As Excel.Workbook)
SetZoom
End Sub
Private Sub oApp_WorkbookOpen(ByVal Wb As Excel.Workbook)
SetZoom
End Sub
Private Sub SetZoom()
ActiveWindow.Zoom = 110
End Sub
Save it as an add-in in your Microsoft Office N:Office:Startup:Excel
folder, or in your Microsoft Excel N:Add-ins, and load it manually
(Tools/Add-ins...).
I've posted the add-in at
ftp://ftp.mcgimpsey.com/excel/zoom.xla
