Set of numbers

[Frank Kabel]

Hi
for the first question try
=SUMPRODUCT(--(MOD(A1:A100,2)=1))

for the second one find below a couple of possible
formulas (depending on the type of your
data): In your case take A.2.d or A.2.e
-------------------
A. Collection of formulas to return the last value in a
COLUMN
depending on the type/structure of data.
1. If you have no blank rows in between use
=OFFSET($A$1,COUNTA($A:$A)-1,0)

2. If you have blank rows in between try the following
depending of the
type of values in your column:
2.a. If you have ONLY text values in column A try
=INDEX(A:A,MATCH(REPT("z",255),A:A))

2.b. If you have ONLY numbers in column A:
=INDEX(A:A,MATCH(9.99999999999999E307,A:A))
or
=LOOKUP(9.99999999999999E307,A:A)

2.c. If you have BOTH types (text and values), but AT
LEAST one text
and one numeric entry
=INDEX(A:A,MAX(MATCH(9.99999999999999E307,A:A),MATCH(REPT
("z",255),A:A)
))

2.d. If you don't know the type of data use the following
array
function (entered with CTRL+SHIFT+ENTER)
=INDEX(A:A,MAX(IF(ISBLANK(A:A),0,ROW(A:A))))
or
=LOOKUP(2,1/(1-ISBLANK(A1:A1000)),A1:A1000)
(thanks to Harlan Grove for this formula)
Note: Does not work with range references like A:A


2.e If you don't want to count formula results like ="" as
entry adapt
2.d. as follows:
=INDEX(A:A,MAX(IF(A:A<>"",0,ROW(A:A))))

----------

B. Collection of formulas to return the last value in a
ROW depending
on
the type/structure of data.
1. If you have no blank columns in between use
=OFFSET($A$1,0,COUNTA($1:$1)-1)

2. If you have blank columns in between try the following
depending of
the type of values in your row:
2.a. If you have ONLY text values in column A try
=INDEX(1:1,1,MATCH(REPT("z",255),1:1))

2.b. If you have ONLY numbers in column A:
=INDEX(1:1,1,MATCH(9.99999999999999E307,1:1))
or
=LOOKUP(9.99999999999999E307,1:1)

2.c. If you have BOTH types (text and values), but AT
LEAST one text
and one numeric entry
=INDEX(1:1,1,MAX(MATCH(9.99999999999999E307,1:1),MATCH(REPT
("z",255),1:
1)))

2.d. If you don't know the type of data use the following
array
function (entered with CTRL+SHIFT+ENTER)
=INDEX(1:1,1,MAX(IF(ISBLANK(1:1),0,COLUMN(1:1))))
or
=LOOKUP(2,1/(1-ISBLANK(1:1)),1:1)
(thanks to Harlan Grove for this formula)

2.e If you don't want to count formula results like ="" as
entry adapt
2.d. as follows:

-----Original Message-----
Hi all

Need your help, once again, if possible.

1 - On each set of numbers, how can i count the ones that are odd.
2 - Is there any way in a column, to know which is the

last cell of a column filled in

 

[Harlan Grove]

2.d. If you don't know the type of data use the following
array function (entered with CTRL+SHIFT+ENTER)
=INDEX(A:A,MAX(IF(ISBLANK(A:A),0,ROW(A:A))))

....

You didn't test this. A:A on its own works when treated as a *range*, but
ISBLANK(A:A) is necessarily an array *result* and not a range, so this
formula template can't handle entire column references.

 

[Frank Kabel]

...

You didn't test this. A:A on its own works when treated as a *range*,
but ISBLANK(A:A) is necessarily an array *result* and not a range, so
this formula template can't handle entire column references.

Hi Harlan
thanks for spotting this. Will change this!
Frank