Statistic: Problem with two one sided t-test

[Rosario]

Dear all,
I have a problem with some statistic calculation.
I have 2 series of measure: the first column is the test series and
the second column if the reference series.
I have to calculate the standard 90% confidence intervals of the ratio
test/reference (T/R) and I have to answer to this question: the
products were considered bioequivalent if the difference between two
compared parameters was found statistically insignificant (P < 0.05)
and 90% confidence intervals for these parameters fell within 80-120%.
I know the result for these series, but I have more to calculate:
90% CI : 88.1-115.6%
Two one-sided t-test probability (Probability for T/R ratio (r) to be
within 0.8 and 1.2) : 0.98
Someone can explain or suggest me an internet reference to solve this
problem.

Thanks a lot


5724.4 5204.49
1518.37 1172.63
1186.72 1720.13
805.7 2390.36
1155.86 762.54
2380.6 3050.71
1077.61 1044.55
1755.64 1760.97
973.11 1196.18
689.05 702.22
1323.86 1399.5
1367.1 232.78
3092.67 3354.46
1730.24 1475.54
1070.01 1381.2
1803.08 1454.36
2507.96 2160.75
2051.32 1192.23
1181.96 1220.58
1097.87 395.9
1339.46 1431.47
3610.07 2995.25
847.34 869.04
1655.91 1436.13
1285.73 3253.84
2044.78 1185.02

 

[Jerry W. Lewis]

Something doesn't add up here. The average of the ratios (128.8%) is
not contained in your confidence interval. Also, either the data
contain some outliers, or you must transform to approximate normality
before using the t-distribution, since the distribution of sample ratios
is skewed (e.g. 1367.1/232.78 = 587.3%)

Jerry

 

[Rosario]

Hi Jarry,
I have done the calculation after a log transformation, but my result
doesn't match the one I have posted.
Either my calculations or the result, I've already posted (I read it
in a sientific article), are wrong... What do you think about?
thanks a lot

 

[Jerry W. Lewis]

What article?

Jerry

Hi Jarry,
I have done the calculation after a log transformation, but my result
doesn't match the one I have posted.
Either my calculations or the result, I've already posted (I read it
in a sientific article), are wrong... What do you think about?
thanks a lot

 

[vontressms]

Rosario,
There are a couple of ways to approach this problem. I start by
specifying two one side hypothesis tests

H01: Mt/Mc <= 0.8 or H02: Mt/Mc >= 1.2

versus

HA1: Mt/Mc > 0.8 and HA2: Mt/Mc < 1.2

where Mt is the mean value of the test and Mc is the mean value of the
control. The combined alternative is what we

are trying to assert as bioequivalence HA: 0.8< Mt/Mc < 1.2. This
scenario of testing is called the

Intersection-Union test since the null hypothesis is a union hypothesis
and the alternative is a intersection

hypothesis. The testing strategy is to accept HA if both H01 rejects at
alpha=0.05 and H02 rejects at alpha=0.05. It

can be shown that this stratagy has an overall type 1 error rate of
0.05 if both tests are level 0.05 tests. They

need not be independent to prove this either. I won't go into the proof
here.

Now, there are a couple of common ways to rewrite H01 and H02 to get
linear hyptheses and then do t-tests. You can

compare arithmetic means:

H01: Mt-0.8Mc <= 0 or H02: Mt-1.2Mc >= 0

or you can compare geometric means

H01: log(Mt)-log(Mc) <= log(0.8) or H02: log(Mt)-log(Mc) >= log(1.2)

A lot of people compare geometric means since these kinds of tests are
often done on blood plasma concentrations of

drugs, which tend to have skewed distributions. The log transformation
pulls the outliers in, and makes the data

more normally distributed. In this case you just have to show that a
two sided 90% confidence interval falls withing

log(0.8) and log(1.2). Personally, I find this hard to interpret since
I geometric means are appropriate (have some

physical meaning) for averaging angles or rates.

I prefer using the arithmetic means since they have a normal
distribution for most data sets because of the central

limit theorem. I just rewrite the hypotheses as linear tests and do the
individual tests. For instance, H01 states

in English that the test mean is less than 80% of the control mean. The
standard errors of the difference in means

has to be modified to incorportate the linear coefficients in the test.

You can also look up Feillers theorem on the ratio of means. For this
data set, you can conclude bioequivelence if

the Feiller interval falls within 0.8 to 1.2.

Now it appears that the data you have are paired observations from
individuals, so the means are correlated between

tests and controls. This adds a difficulty since it becomes a repeated
measures experiment. Bioequivalence studies

are often crossover studies, which makes things even more complicated.

Anyway, I have attached a SAS program that test takes both the
arithmetic means and the geometric means approach

assuming paired observations. My analysis finds bioequivalence in the
arithmetic hypothesis tests, but does not

conclude bioequivalence in the geometric means. I can email you an
output listing if you wish.

Mark Von Tress

data one;
input test control;
sample = _n_;
cards;
5724.4 5204.49
1518.37 1172.63
1186.72 1720.13
805.7 2390.36
1155.86 762.54
2380.6 3050.71
1077.61 1044.55
1755.64 1760.97
973.11 1196.18
689.05 702.22
1323.86 1399.5
1367.1 232.78
3092.67 3354.46
1730.24 1475.54
1070.01 1381.2
1803.08 1454.36
2507.96 2160.75
2051.32 1192.23
1181.96 1220.58
1097.87 395.9
1339.46 1431.47
3610.07 2995.25
847.34 869.04
1655.91 1436.13
1285.73 3253.84
2044.78 1185.02
;
proc univariate data=one plot normal;
var test control;
run;
proc sort data=one; by sample;
proc transpose data=one out=onet;
by sample;
var test control;
run;
data onet;
set onet;
log_c = log10(col1);
rename col1=conc _name_=group;
run;

*raw data - test equivalence of arithmetic means;
proc mixed data=onet ratio covtest;
class group sample;
model conc = group / ddfm=satterth solution noint;
random sample;
estimate 'test 1 H01: -0.8control + 1.0 test > 0' group -0.8 1 /
upper;
estimate 'test 2 H02: -1.2control + 1.0 test < 0' group -1.2 1 /
lower;
* reject both H01 and H02, so conclude bioequivalence;
run;

*log data - test equivalence of geometric means;
proc mixed data=onet ratio covtest;
class group sample;
model log_c = group / ddfm=satterth solution noint;
random sample;
estimate 'difference in geometric means' group -1 1 / cl alpha=0.1;
* test rule: accept bioequivalence at alpha = 0.05
if 2 sided 90% confidence interval (i.e. 2 one sided 95% ci's)
on difference in mean log_c falls within log10(0.8)=-.1 and
log10(1.2)=0.08;
* Using results: do not accept bioequivalence since
lci=-0.04297 > -0.1, but uci=0.1149 > 0.08;
run;