Sumproduct Wildcards

[steven.britton]

This works =Sumif($A3$:$A$43,"*Helm*",$F$3:$F$43)

Now I want to do that if TWO conditions are met, I typically use an
Array and Sumproduct, but can't get it to work. Thoughts?

It would the equivalent of doing this: =SUMPRODUCT(($F$3:$F$43)*($A
$3:$A$43="*Helm*")*($B$3:$B$43="*Port*")). But that doesn't work...

 

[RagDyeR]

Try this:

=SUMPRODUCT((ISNUMBER(SEARCH("Helm",$A$3:$A$43)))*(ISNUMBER(SEARCH("Port",$B$3:$B$43)))*$F$3:$F$43)

--

HTH,

RD
=====================================================
Please keep all correspondence within the Group, so all may benefit!
=====================================================

This works =Sumif($A3$:$A$43,"*Helm*",$F$3:$F$43)

Now I want to do that if TWO conditions are met, I typically use an
Array and Sumproduct, but can't get it to work. Thoughts?

It would the equivalent of doing this: =SUMPRODUCT(($F$3:$F$43)*($A
$3:$A$43="*Helm*")*($B$3:$B$43="*Port*")). But that doesn't work...

 

[Glenn]

This works =Sumif($A3$:$A$43,"*Helm*",$F$3:$F$43)

Now I want to do that if TWO conditions are met, I typically use an
Array and Sumproduct, but can't get it to work. Thoughts?

It would the equivalent of doing this: =SUMPRODUCT(($F$3:$F$43)*($A
$3:$A$43="*Helm*")*($B$3:$B$43="*Port*")). But that doesn't work...

=SUMPRODUCT(($F$3:$F$43)*
(ISNUMBER(FIND("Helm",$A$3:$A$43)))*
(ISNUMBER(FIND("Port",$B$3:$B$43))))

 

[Luke M]

You could try using this function, since the SEARCH function supports
wildcards.

=SUMPRODUCT(($F$3:$F$43)*(ISNUMBER(SEARCH("*Helm*",$A$3:$A$43)))*ISNUMBER(SEARCH("*Port*",$B$3:$B$43)))

Note that SEARCH is non-case sensitive. If you want it to be, replace the
SEARCH's with FIND's.

 

[Glenn]

You could try using this function, since the SEARCH function supports
wildcards.

=SUMPRODUCT(($F$3:$F$43)*(ISNUMBER(SEARCH("*Helm*",$A$3:$A$43)))*ISNUMBER(SEARCH("*Port*",$B$3:$B$43)))

Note that SEARCH is non-case sensitive. If you want it to be, replace the
SEARCH's with FIND's.

What is the difference between

=ISNUMBER(SEARCH("Helm",$A$3:$A$43))

and

=ISNUMBER(SEARCH("*Helm*",$A$3:$A$43))

 

[Luke M]

In this instance, none really. I was just copying OP's text. However, if you
wanted to check if a cell contained two or more words, it is nice to know you
can use wildcards.

E.g.
=SEARCH("bob*tom",A1)
would check look for the word bob followed sometime by the word tom. (also
supports the '?' character for single character wildcard.