Use FIND for / or \ or -

[Bert]

appy New Year all,
I want to use the FIND function with LEFT to extract the numbers left of a
marker which could be / or \ or -
I can only see how to use FIND for one character how to use for multiple
possibilites? (so when FIND reaches / or \ or - it returns the position)
Thanks for any suggestions
Bert

 

[RagDyeR]

Try this:

=LEFT(A1,MIN(FIND({"/","\","-"},A1&"/\-"))-1)

And copy down as needed.
--

HTH,

RD
=====================================================
Please keep all correspondence within the Group, so all may benefit!
=====================================================

appy New Year all,
I want to use the FIND function with LEFT to extract the numbers left of a
marker which could be / or \ or -
I can only see how to use FIND for one character how to use for multiple
possibilites? (so when FIND reaches / or \ or - it returns the position)
Thanks for any suggestions
Bert

 

[Gary''s Student]

Instead of using:
=FIND()
use
=IF(ISERROR(FIND("-",A1,1)),0,FIND("-",A1,1))+IF(ISERROR(FIND("\",A1,1)),0,FIND("\",A1,1))+IF(ISERROR(FIND("/",A1,1)),0,FIND("/",A1,1))

 

[CLR]

Playing off of RD's really nifty solution, this one will return a blank if
there is no occurance of \, /, or- in the cells

=IF(LEFT(A1,MIN(FIND({"/","\","-"},A1&"/\-"))-1)=A1,"",LEFT(A1,MIN(FIND({"/","\","-"},A1&"/\-"))-1))

Vaya con Dios,
Chuck, CABGx3

 

[Teethless mama]

Another way...

=LEFT(A1,FIND("^",SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1,"\","^"),"/","^"),"-","^"))-1)

 

[Bert]

Thanks for all your solutions as I see a use for them in other work

Bert

 

[Rick Rothstein \(MVP - VB\)]

Why not just pick one of the search characters and then do only two
substitutions (one for each of the other characters)...

=LEFT(A1,FIND("\",SUBSTITUTE(SUBSTITUTE(A1,"/","\"),"-","\"))-1)

Rick

 

[Harlan Grove]

Playing off of RD's really nifty solution, this one will return a
blank if there is no occurance of \, /, or- in the cells

=IF(LEFT(A1,MIN(FIND({"/","\","-"},A1&"/\-"))-1)=A1,
"",LEFT(A1,MIN(FIND({"/","\","-"},A1&"/\-"))-1))

....

No need for multiple FIND calls.

=SUBSTITUTE(LEFT(A1,MIN(FIND({"/","\","-"},A1&"/\-"))-1),A1,"")