Web address

[M/S 2007 Toolbar (Web) address?]

I just had M/S Word 2007 installed. The prior edition had a area on the
toolbar that supplied the location of the current document I was working
from. It was listed in the Web toolbar and it resembled a window that
contained the path to the document and the drive. I would use the feature to
cut and paste the path of the document into messages when I wanted someone to
view the document I was working with.

Does anyone have an idea if the feature still exists in the 2007 edition?

 

[Doug Robbins - Word MVP]

Add the Document Location item (from either the All Commands or Commands Not
in Ribbon) group to the Quick Access Toolbar

--
Hope this helps,

Doug Robbins - Word MVP

Please reply only to the newsgroups unless you wish to obtain my services on
a paid professional basis.

"M/S 2007 Toolbar (Web) address?" <M/S 2007 Toolbar (Web)
[email protected]> wrote in message
news:[email protected]...

 

[Graham Mayor]

As Doug indicates, the feature is still available, but it takes up a lot of
limited real estate. It might be better to display the document name in the
Window title and use a macro to copy the path to the clipboard.

The former can be achieved by adding the following line to the end of an
autoopen macro in the normal template

ActiveWindow.Caption = ActiveDocument.FullName

The latter with the following macro:

Sub CopyFilenameAndPath()
Dim dFname As DataObject
Dim fFname As String
Set dFname = New DataObject
On Error Resume Next
With ActiveDocument
If Len(.Path) = 0 Then .Save
fFname = .FullName
End With
dFname.SetText fFname
dFname.PutInClipboard
End Sub

http://www.gmayor.com/installing_macro.htm


If you use very long path/document names, there may not be enough space in
the Window title bar to display them. You can get over this by limiting what
is displayed - in the example below to 120 characters - This handy macro was
reproduced a couple of years back by one of my fellow MVPs - Jay Freedman.
You can call it from an autoopen macro in place of the line -
ActiveWindow.Caption = ActiveDocument.FullName

Sub InsertDocTitle()
' Changes window title to include path with filename
Dim NameArray As Variant
Dim NameStringL As String
Dim NameStringR As String
Dim Count As Long
Const maxLen = 120 ' set this value to fit your window width
' (avoid error if no active window)
If Windows.Count > 0 Then
NameStringL = ActiveDocument.FullName
If Len(NameStringL) > maxLen Then
' separate the folder names
NameArray = Split(NameStringL, "\")
' check the folder depth
Count = UBound(NameArray)
If Count > 3 Then
NameStringL = NameArray(0) & "\...\"
NameStringR = NameArray(Count)
Count = Count - 1
' continue adding folders to the left of the string
' until you run out of folders or one won't fit
Do While (Count > 0) And _
(Len(NameStringL) + Len(NameStringR) + _
Len(NameArray(Count)) < maxLen)
NameStringR = NameArray(Count) & "\" _
& NameStringR
Count = Count - 1
Loop
NameStringL = NameStringL & NameStringR
End If
End If
' Change the window's caption
ActiveWindow.Caption = NameStringL
End If
End Sub

--
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>
Graham Mayor - Word MVP


<>>< ><<> ><<> <>>< ><<> <>>< <>><<>

"M/S 2007 Toolbar (Web) address?" <M/S 2007 Toolbar (Web)
[email protected]> wrote in message